Revision bump for 2.11.8
[ganeti-github.git] / configure.ac
1 # Configure script for Ganeti
2 m4_define([gnt_version_major], [2])
3 m4_define([gnt_version_minor], [11])
4 m4_define([gnt_version_revision], [8])
5 m4_define([gnt_version_suffix], [])
6 m4_define([gnt_version_full],
7           m4_format([%d.%d.%d%s],
8                     gnt_version_major, gnt_version_minor,
9                     gnt_version_revision, gnt_version_suffix))
10
11 AC_PREREQ(2.59)
12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
13 AC_CONFIG_AUX_DIR(autotools)
14 AC_CONFIG_SRCDIR(configure)
15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability]
16                  m4_esyscmd([case `automake --version | head -n 1` in
17                              *1.11*);;
18                              *) echo serial-tests;;
19                              esac]))
20
21 AC_SUBST([VERSION_MAJOR], gnt_version_major)
22 AC_SUBST([VERSION_MINOR], gnt_version_minor)
23 AC_SUBST([VERSION_REVISION], gnt_version_revision)
24 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
25 AC_SUBST([VERSION_FULL], gnt_version_full)
26
27 AC_SUBST([BINDIR], $bindir)
28 AC_SUBST([SBINDIR], $sbindir)
29 AC_SUBST([MANDIR], $mandir)
30
31 # --enable-versionfull
32 AC_ARG_ENABLE([versionfull],
33   [AS_HELP_STRING([--enable-versionfull],
34                   m4_normalize([use the full version string rather
35                   than major.minor for version directories]))],
36   [[if test "$enableval" != no; then
37       USE_VERSION_FULL=yes
38     else
39       USER_VERSION_FULL=no
40     fi
41   ]],
42   [USE_VERSION_FULL=no
43   ])
44 AC_SUBST(USE_VERSION_FULL, $USE_VERSION_FULL)
45 AM_CONDITIONAL([USE_VERSION_FULL], [test "$USE_VERSION_FULL" = yes])
46
47 # --enable-symlinks
48 AC_ARG_ENABLE([symlinks],
49   [AS_HELP_STRING([--enable-symlinks],
50                   m4_normalize([also install version-dependent symlinks under
51                   $sysconfdir (default: disabled)]))],
52   [[if test "$enableval" != yes; then
53       INSTALL_SYMLINKS=no
54     else
55       INSTALL_SYMLINKS=yes
56     fi
57   ]],
58   [INSTALL_SYMLINKS=no
59   ])
60 AC_SUBST(INSTALL_SYMLINKS, $INSTALL_SYMLINKS)
61 AM_CONDITIONAL([INSTALL_SYMLINKS], [test "$INSTALL_SYMLINKS" = yes])
62
63 # --enable-haskell-profiling
64 AC_ARG_ENABLE([haskell-profiling],
65   [AS_HELP_STRING([--enable-haskell-profiling],
66                   m4_normalize([enable profiling for Haskell binaries
67                   (default: disabled)]))],
68   [[if test "$enableval" != yes; then
69       HPROFILE=no
70     else
71       HPROFILE=yes
72     fi
73   ]],
74   [HPROFILE=no
75   ])
76 AC_SUBST(HPROFILE, $HPROFILE)
77 AM_CONDITIONAL([HPROFILE], [test "$HPROFILE" = yes])
78
79 # --enable-haskell-coverage
80 AC_ARG_ENABLE([haskell-coverage],
81   [AS_HELP_STRING([--enable-haskell-coverage],
82                   m4_normalize([enable coverage for Haskell binaries
83                   (default: disabled)]))],
84   [[if test "$enableval" != yes; then
85       HCOVERAGE=no
86     else
87       HCOVERAGE=yes
88     fi
89   ]],
90   [HCOVERAGE=no
91   ])
92 AC_SUBST(HCOVERAGE, $HCOVERAGE)
93 AM_CONDITIONAL([HCOVERAGE], [test "$HCOVERAGE" = yes])
94
95 # --enable-haskell-tests
96 AC_ARG_ENABLE([haskell-tests],
97   [AS_HELP_STRING([--enable-haskell-tests],
98                   m4_normalize([enable additinal Haskell development test code
99                   (default: disabled)]))],
100   [[if test "$enableval" != yes; then
101       HTEST=no
102     else
103       HTEST=yes
104     fi
105   ]],
106   [HTEST=no
107   ])
108 AC_SUBST(HTEST, $HTEST)
109 AM_CONDITIONAL([HTEST], [test "$HTEST" = yes])
110
111 # --enable-developer-mode
112 AC_ARG_ENABLE([developer-mode],
113   [AS_HELP_STRING([--enable-developer-mode],
114                   m4_normalize([do a developper build with additional
115                   checks and fatal warnings; this is implied by enabling
116                   the haskell tests]))],
117   [[if test "$enableval" != no; then
118       DEVELOPER_MODE=yes
119     else
120       DEVELOPER_MODE=no
121     fi
122   ]],
123   [DEVELOPER_MODE=no
124   ])
125 AC_SUBST(DEVELOPER_MODE, $DEVELOPER_MODE)
126 AM_CONDITIONAL([DEVELOPER_MODE],
127                [test "$DEVELOPER_MODE" = yes -o "$HTEST" = yes])
128
129 # --with-haskell-flags=
130 AC_ARG_WITH([haskell-flags],
131   [AS_HELP_STRING([--with-haskell-flags=FLAGS],
132     [Extra flags to pass to GHC]
133   )],
134   [hextra_configure="$withval"],
135   [hextra_configure=""])
136 AC_SUBST(HEXTRA_CONFIGURE, $hextra_configure)
137
138 # --with-ssh-initscript=...
139 AC_ARG_WITH([ssh-initscript],
140   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
141     [SSH init script to use (default is /etc/init.d/ssh)]
142   )],
143   [ssh_initd_script="$withval"],
144   [ssh_initd_script="/etc/init.d/ssh"])
145 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
146
147 # --with-export-dir=...
148 AC_ARG_WITH([export-dir],
149   [AS_HELP_STRING([--with-export-dir=DIR],
150     [directory to use by default for instance image]
151     [ exports (default is /srv/ganeti/export)]
152   )],
153   [export_dir="$withval"],
154   [export_dir="/srv/ganeti/export"])
155 AC_SUBST(EXPORT_DIR, $export_dir)
156
157 # --with-backup-dir=...
158 AC_ARG_WITH([backup-dir],
159   [AS_HELP_STRING([--with-backup-dir=DIR],
160     [directory to use for configuration backups]
161     [ on Ganeti upgrades (default is $(localstatedir)/lib)]
162   )],
163   [backup_dir="$withval"
164    USE_BACKUP_DIR=yes
165   ],
166   [backup_dir=
167    USE_BACKUP_DIR=no
168   ])
169 AC_SUBST(BACKUP_DIR, $backup_dir)
170 AM_CONDITIONAL([USE_BACKUP_DIR], [test "$USE_BACKUP_DIR" = yes])
171
172 # --with-ssh-config-dir=...
173 AC_ARG_WITH([ssh-config-dir],
174   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
175     [ directory with ssh host keys ]
176     [ (default is /etc/ssh)]
177   )],
178   [ssh_config_dir="$withval"],
179   [ssh_config_dir="/etc/ssh"])
180 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
181
182 # --with-xen-config-dir=...
183 AC_ARG_WITH([xen-config-dir],
184   [AS_HELP_STRING([--with-xen-config-dir=DIR],
185                   m4_normalize([Xen configuration directory
186                                 (default: /etc/xen)]))],
187   [xen_config_dir="$withval"],
188   [xen_config_dir=/etc/xen])
189 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
190
191 # --with-os-search-path=...
192 AC_ARG_WITH([os-search-path],
193   [AS_HELP_STRING([--with-os-search-path=LIST],
194     [comma separated list of directories to]
195     [ search for OS images (default is /srv/ganeti/os)]
196   )],
197   [os_search_path="$withval"],
198   [os_search_path="/srv/ganeti/os"])
199 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
200
201 # --with-extstorage-search-path=...
202 AC_ARG_WITH([extstorage-search-path],
203   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
204     [comma separated list of directories to]
205     [ search for External Storage Providers]
206     [ (default is /srv/ganeti/extstorage)]
207   )],
208   [es_search_path="$withval"],
209   [es_search_path="/srv/ganeti/extstorage"])
210 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
211
212 # --with-iallocator-search-path=...
213 AC_ARG_WITH([iallocator-search-path],
214   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
215     [comma separated list of directories to]
216     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
217   )],
218   [iallocator_search_path="$withval"],
219   [iallocator_search_path="$libdir/$PACKAGE_NAME/iallocators"])
220 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
221
222 # --with-xen-bootloader=...
223 AC_ARG_WITH([xen-bootloader],
224   [AS_HELP_STRING([--with-xen-bootloader=PATH],
225     [bootloader for Xen hypervisor (default is empty)]
226   )],
227   [xen_bootloader="$withval"],
228   [xen_bootloader=])
229 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
230
231 # --with-xen-kernel=...
232 AC_ARG_WITH([xen-kernel],
233   [AS_HELP_STRING([--with-xen-kernel=PATH],
234     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
235   )],
236   [xen_kernel="$withval"],
237   [xen_kernel="/boot/vmlinuz-3-xenU"])
238 AC_SUBST(XEN_KERNEL, $xen_kernel)
239
240 # --with-xen-initrd=...
241 AC_ARG_WITH([xen-initrd],
242   [AS_HELP_STRING([--with-xen-initrd=PATH],
243     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
244   )],
245   [xen_initrd="$withval"],
246   [xen_initrd="/boot/initrd-3-xenU"])
247 AC_SUBST(XEN_INITRD, $xen_initrd)
248
249 # --with-kvm-kernel=...
250 AC_ARG_WITH([kvm-kernel],
251   [AS_HELP_STRING([--with-kvm-kernel=PATH],
252     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
253   )],
254   [kvm_kernel="$withval"],
255   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
256 AC_SUBST(KVM_KERNEL, $kvm_kernel)
257
258 # --with-kvm-path=...
259 AC_ARG_WITH([kvm-path],
260   [AS_HELP_STRING([--with-kvm-path=PATH],
261     [absolute path to the kvm binary]
262     [ (default is /usr/bin/kvm)]
263   )],
264   [kvm_path="$withval"],
265   [kvm_path="/usr/bin/kvm"])
266 AC_SUBST(KVM_PATH, $kvm_path)
267
268 # --with-lvm-stripecount=...
269 AC_ARG_WITH([lvm-stripecount],
270   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
271     [the default number of stripes to use for LVM volumes]
272     [ (default is 1)]
273   )],
274   [lvm_stripecount="$withval"],
275   [lvm_stripecount=1])
276 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
277
278 # --with-ssh-login-user=...
279 AC_ARG_WITH([ssh-login-user],
280   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
281     [user to use for SSH logins within the cluster (default is root)]
282   )],
283   [ssh_login_user="$withval"],
284   [ssh_login_user=root])
285 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
286
287 # --with-ssh-console-user=...
288 AC_ARG_WITH([ssh-console-user],
289   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
290     [user to use for SSH logins to access instance consoles (default is root)]
291   )],
292   [ssh_console_user="$withval"],
293   [ssh_console_user=root])
294 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
295
296 # --with-default-user=...
297 AC_ARG_WITH([default-user],
298   [AS_HELP_STRING([--with-default-user=USERNAME],
299     [default user for daemons]
300     [ (default is to run all daemons as root)]
301   )],
302   [user_default="$withval"],
303   [user_default=root])
304
305 # --with-default-group=...
306 AC_ARG_WITH([default-group],
307   [AS_HELP_STRING([--with-default-group=GROUPNAME],
308     [default group for daemons]
309     [ (default is to run all daemons under group root)]
310   )],
311   [group_default="$withval"],
312   [group_default=root])
313
314 # --with-user-prefix=...
315 AC_ARG_WITH([user-prefix],
316   [AS_HELP_STRING([--with-user-prefix=PREFIX],
317     [prefix for daemon users]
318     [ (default is to run all daemons as root; use --with-default-user]
319     [ to change the default)]
320   )],
321   [user_masterd="${withval}masterd";
322    user_rapi="${withval}rapi";
323    user_confd="${withval}confd";
324    user_kvmd="$user_default";
325    user_luxid="${withval}masterd";
326    user_noded="$user_default";
327    user_mond="$user_default"],
328   [user_masterd="$user_default";
329    user_rapi="$user_default";
330    user_confd="$user_default";
331    user_kvmd="$user_default";
332    user_luxid="$user_default";
333    user_noded="$user_default";
334    user_mond="$user_default"])
335 AC_SUBST(MASTERD_USER, $user_masterd)
336 AC_SUBST(RAPI_USER, $user_rapi)
337 AC_SUBST(CONFD_USER, $user_confd)
338 AC_SUBST(KVMD_USER, $user_kvmd)
339 AC_SUBST(LUXID_USER, $user_luxid)
340 AC_SUBST(NODED_USER, $user_noded)
341 AC_SUBST(MOND_USER, $user_mond)
342
343 # --with-group-prefix=...
344 AC_ARG_WITH([group-prefix],
345   [AS_HELP_STRING([--with-group-prefix=PREFIX],
346     [prefix for daemon POSIX groups]
347     [ (default is to run all daemons under group root; use]
348     [ --with-default-group to change the default)]
349   )],
350   [group_rapi="${withval}rapi";
351    group_admin="${withval}admin";
352    group_confd="${withval}confd";
353    group_kvmd="$group_default";
354    group_luxid="${withval}luxid";
355    group_masterd="${withval}masterd";
356    group_noded="$group_default";
357    group_daemons="${withval}daemons";
358    group_mond="$group_default"],
359   [group_rapi="$group_default";
360    group_admin="$group_default";
361    group_confd="$group_default";
362    group_kvmd="$group_default";
363    group_luxid="$group_default";
364    group_masterd="$group_default";
365    group_noded="$group_default";
366    group_daemons="$group_default";
367    group_mond="$group_default"])
368 AC_SUBST(RAPI_GROUP, $group_rapi)
369 AC_SUBST(ADMIN_GROUP, $group_admin)
370 AC_SUBST(CONFD_GROUP, $group_confd)
371 AC_SUBST(KVMD_GROUP, $group_kvmd)
372 AC_SUBST(LUXID_GROUP, $group_luxid)
373 AC_SUBST(MASTERD_GROUP, $group_masterd)
374 AC_SUBST(NODED_GROUP, $group_noded)
375 AC_SUBST(DAEMONS_GROUP, $group_daemons)
376 AC_SUBST(MOND_GROUP, $group_mond)
377
378 # Print the config to the user
379 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
380 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
381 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
382 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
383 AC_MSG_NOTICE([Group for daemons is $group_daemons])
384 AC_MSG_NOTICE([Group for clients is $group_admin])
385
386 # --enable-drbd-barriers
387 AC_ARG_ENABLE([drbd-barriers],
388   [AS_HELP_STRING([--enable-drbd-barriers],
389                   m4_normalize([enable the DRBD barriers functionality by
390                                 default (>= 8.0.12) (default: enabled)]))],
391   [[if test "$enableval" != no; then
392       DRBD_BARRIERS=n
393       DRBD_NO_META_FLUSH=False
394     else
395       DRBD_BARRIERS=bf
396       DRBD_NO_META_FLUSH=True
397     fi
398   ]],
399   [DRBD_BARRIERS=n
400    DRBD_NO_META_FLUSH=False
401   ])
402 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
403 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
404
405 # --enable-syslog[=no/yes/only]
406 AC_ARG_ENABLE([syslog],
407   [AS_HELP_STRING([--enable-syslog],
408     [enable use of syslog (default: disabled), one of no/yes/only])],
409   [[case "$enableval" in
410       no)
411         SYSLOG=no
412         ;;
413       yes)
414         SYSLOG=yes
415         ;;
416       only)
417         SYSLOG=only
418         ;;
419       *)
420         SYSLOG=
421         ;;
422     esac
423   ]],
424   [SYSLOG=no])
425
426 if test -z "$SYSLOG"
427 then
428   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
429 fi
430 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
431
432 # --enable-restricted-commands[=no/yes]
433 AC_ARG_ENABLE([restricted-commands],
434   [AS_HELP_STRING([--enable-restricted-commands],
435                   m4_normalize([enable restricted commands in the node daemon
436                                 (default: disabled)]))],
437   [[if test "$enableval" = no; then
438       enable_restricted_commands=False
439     else
440       enable_restricted_commands=True
441     fi
442   ]],
443   [enable_restricted_commands=False])
444 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
445
446 # --with-disk-separator=...
447 AC_ARG_WITH([disk-separator],
448   [AS_HELP_STRING([--with-disk-separator=STRING],
449     [Disk index separator, useful if the default of ':' is handled]
450     [ specially by the hypervisor]
451   )],
452   [disk_separator="$withval"],
453   [disk_separator=":"])
454 AC_SUBST(DISK_SEPARATOR, $disk_separator)
455
456 # Check common programs
457 AC_PROG_INSTALL
458 AC_PROG_LN_S
459
460 # check if ln is the GNU version of ln (and hence supports -T)
461 if ln --version 2> /dev/null | head -1 | grep -q GNU
462 then
463   AC_SUBST(HAS_GNU_LN, True)
464 else
465   AC_SUBST(HAS_GNU_LN, False)
466 fi
467
468 # Check for the ip command
469 AC_ARG_VAR(IP_PATH, [ip path])
470 AC_PATH_PROG(IP_PATH, [ip], [])
471 if test -z "$IP_PATH"
472 then
473   AC_MSG_ERROR([ip command not found])
474 fi
475
476 # Check for pandoc
477 AC_ARG_VAR(PANDOC, [pandoc path])
478 AC_PATH_PROG(PANDOC, [pandoc], [])
479 if test -z "$PANDOC"
480 then
481   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
482 fi
483
484 # Check for python-sphinx
485 AC_ARG_VAR(SPHINX, [sphinx-build path])
486 AC_PATH_PROG(SPHINX, [sphinx-build], [])
487 if test -z "$SPHINX"
488 then
489   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
490                             not be possible]))
491 else
492   # Sphinx exits with code 1 when it prints its usage
493   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
494
495   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
496     AC_MSG_ERROR([Unable to determine Sphinx version])
497
498   # Note: Character classes ([...]) need to be double quoted due to autoconf
499   # using m4
500   elif ! echo "$sphinxver" | grep -q -E \
501        '^Sphinx([[[:space:]]]+|\(sphinx-build[[1-9]]?\)|v)*[[1-9]]\>'; then
502     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
503   fi
504 fi
505 AM_CONDITIONAL([HAS_SPHINX], [test -n "$SPHINX"])
506
507 AC_ARG_ENABLE([manpages-in-doc],
508   [AS_HELP_STRING([--enable-manpages-in-doc],
509                   m4_normalize([include man pages in HTML documentation
510                                 (requires sphinx; default disabled)]))],
511   [case "$enableval" in
512       yes) manpages_in_doc=yes ;;
513       no) manpages_in_doc= ;;
514       *)
515         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
516         ;;
517     esac
518   ],
519   [manpages_in_doc=])
520 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
521 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
522
523 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
524   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
525 fi
526
527 # Check for graphviz (dot)
528 AC_ARG_VAR(DOT, [dot path])
529 AC_PATH_PROG(DOT, [dot], [])
530 if test -z "$DOT"
531 then
532   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
533                             documentation rebuild not possible]))
534 fi
535
536 # Check for pylint
537 AC_ARG_VAR(PYLINT, [pylint path])
538 AC_PATH_PROG(PYLINT, [pylint], [])
539 if test -z "$PYLINT"
540 then
541   AC_MSG_WARN([pylint not found, checking code will not be possible])
542 fi
543
544 # Check for pep8
545 AC_ARG_VAR(PEP8, [pep8 path])
546 AC_PATH_PROG(PEP8, [pep8], [])
547 if test -z "$PEP8"
548 then
549   AC_MSG_WARN([pep8 not found, checking code will not be complete])
550 fi
551 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
552
553 # Check for python-coverage
554 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
555 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
556 if test -z "$PYCOVERAGE"
557 then
558   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
559                             Python test coverage will not be possible]))
560 fi
561
562 # Check for socat
563 AC_ARG_VAR(SOCAT, [socat path])
564 AC_PATH_PROG(SOCAT, [socat], [])
565 if test -z "$SOCAT"
566 then
567   AC_MSG_ERROR([socat not found])
568 fi
569
570 # Check for qemu-img
571 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
572 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
573 if test -z "$QEMUIMG_PATH"
574 then
575   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
576 fi
577
578 # --enable-confd
579 ENABLE_CONFD=
580 AC_ARG_ENABLE([confd],
581   [AS_HELP_STRING([--enable-confd],
582   [enable the ganeti-confd daemon (default: check)])],
583   [],
584   [enable_confd=check])
585
586 ENABLE_MOND=
587 AC_ARG_ENABLE([monitoring],
588   [AS_HELP_STRING([--enable-monitoring],
589   [enable the ganeti monitoring daemon (default: check)])],
590   [],
591   [enable_monitoring=check])
592
593 # Check for ghc
594 AC_ARG_VAR(GHC, [ghc path])
595 AC_PATH_PROG(GHC, [ghc], [])
596 if test -z "$GHC"; then
597   AC_MSG_FAILURE([ghc not found, compilation will not possible])
598 fi
599
600 AC_MSG_CHECKING([checking for extra GHC flags])
601 GHC_BYVERSION_FLAGS=
602 # check for GHC supported flags that vary accross versions
603 for flag in -fwarn-incomplete-uni-patterns; do
604   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
605    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
606   fi
607 done
608 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
609 AC_SUBST(GHC_BYVERSION_FLAGS)
610
611 # Check for ghc-pkg
612 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
613 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
614 if test -z "$GHC_PKG"; then
615   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
616 fi
617
618 # check for modules, first custom/special checks
619 AC_MSG_NOTICE([checking for required haskell modules])
620 HS_PARALLEL3=
621 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
622                  [AC_GHC_PKG_REQUIRE(parallel)], t)
623 AC_SUBST(HS_PARALLEL3)
624
625 # and now standard modules
626 AC_GHC_PKG_REQUIRE(curl)
627 AC_GHC_PKG_REQUIRE(json)
628 AC_GHC_PKG_REQUIRE(network)
629 AC_GHC_PKG_REQUIRE(mtl)
630 AC_GHC_PKG_REQUIRE(bytestring)
631 AC_GHC_PKG_REQUIRE(base64-bytestring-1.*, t)
632 AC_GHC_PKG_REQUIRE(utf8-string)
633 AC_GHC_PKG_REQUIRE(zlib)
634 AC_GHC_PKG_REQUIRE(hslogger)
635 AC_GHC_PKG_REQUIRE(process)
636 AC_GHC_PKG_REQUIRE(attoparsec)
637 AC_GHC_PKG_REQUIRE(vector)
638 AC_GHC_PKG_REQUIRE(text)
639 AC_GHC_PKG_REQUIRE(hinotify)
640 AC_GHC_PKG_REQUIRE(Crypto)
641
642 # extra modules for confd functionality; also needed for tests
643 HS_NODEV=
644 CONFD_PKG=
645 # if a new confd dependency is needed, add it here like:
646 # AC_GHC_PKG_CHECK([somepkg], [], [HS_NODEV=1; CONFD_PKG="$CONFD_PKG somepkg"])
647 HS_REGEX_PCRE=-DNO_REGEX_PCRE
648 AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
649                  [HS_NODEV=1; CONFD_PKG="$CONFD_PKG regex-pcre"])
650
651 has_confd=False
652 if test "$enable_confd" != no; then
653   if test -z "$CONFD_PKG"; then
654     has_confd=True
655   elif test "$enable_confd" = check; then
656     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
657                               not found ($CONFD_PKG), confd disabled]))
658   else
659     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
660                                  required libraries were not found:
661                                  $CONFD_PKG]))
662   fi
663 fi
664 AC_SUBST(HS_REGEX_PCRE)
665 if test "$has_confd" = True; then
666   AC_MSG_NOTICE([Enabling confd usage])
667 fi
668 AC_SUBST(ENABLE_CONFD, $has_confd)
669 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
670
671 #extra modules for monitoring daemon functionality; also needed for tests
672 MONITORING_PKG=
673 AC_GHC_PKG_CHECK([snap-server], [],
674                  [NS_NODEV=1; MONITORING_PKG="$MONITORING_PKG snap-server"])
675
676 has_monitoring=False
677 if test "$enable_monitoring" != no; then
678   MONITORING_DEP=
679   if test "$has_confd" = False; then
680     MONITORING_DEP="$MONITORING_DEP confd"
681   fi
682   has_monitoring_pkg=False
683   if test -z "$MONITORING_PKG"; then
684     has_monitoring_pkg=True
685   elif test "$enable_monitoring" = check; then
686     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
687                               daemon were not found ($MONITORING_PKG),
688                               monitoring disabled]))
689   else
690     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
691                                  required libraries were not found:
692                                  $MONITORING_PKG]))
693   fi
694   has_monitoring_dep=False
695   if test -z "$MONITORING_DEP"; then
696     has_monitoring_dep=True
697   elif test "$enable_monitoring" = check; then
698     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
699                               monitoring agent were not enabled
700                               ($MONITORING_DEP), monitoring disabled]))
701   else
702     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
703                                  required optional Ganeti components were not
704                                  found: $MONITORING_DEP]))
705   fi
706
707 fi
708 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
709   has_monitoring=True
710   AC_MSG_NOTICE([Enabling the monitoring agent usage])
711 fi
712 AC_SUBST(ENABLE_MOND, $has_monitoring)
713 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
714
715 # development modules
716 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
717 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
718 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
719 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
720 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
721 if test -n "$HS_NODEV"; then
722    AC_MSG_WARN(m4_normalize([Required development modules were not found,
723                              you won't be able to run Haskell unittests]))
724 else
725    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
726 fi
727 AC_SUBST(HS_NODEV)
728 AM_CONDITIONAL([HS_UNIT], [test -n $HS_NODEV])
729
730 # Check for HsColour
731 HS_APIDOC=no
732 AC_ARG_VAR(HSCOLOUR, [HsColour path])
733 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
734 if test -z "$HSCOLOUR"; then
735   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
736                             not be generated]))
737 fi
738
739 # Check for haddock
740 AC_ARG_VAR(HADDOCK, [haddock path])
741 AC_PATH_PROG(HADDOCK, [haddock], [])
742 if test -z "$HADDOCK"; then
743   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
744                             not be generated]))
745 fi
746 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
747   HS_APIDOC=yes
748 fi
749 AC_SUBST(HS_APIDOC)
750
751 # Check for hlint
752 AC_ARG_VAR(HLINT, [hlint path])
753 AC_PATH_PROG(HLINT, [hlint], [])
754 if test -z "$HLINT"; then
755   AC_MSG_WARN([hlint not found, checking code will not be possible])
756 fi
757
758 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
759 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
760 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
761
762 # Check for fakeroot
763 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
764 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
765 if test -z "$FAKEROOT_PATH"; then
766   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
767                             will not be executed]))
768 fi
769 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
770
771 SOCAT_USE_ESCAPE=
772 AC_ARG_ENABLE([socat-escape],
773   [AS_HELP_STRING([--enable-socat-escape],
774     [use escape functionality available in socat >= 1.7 (default: detect
775      automatically)])],
776   [[if test "$enableval" = yes; then
777       SOCAT_USE_ESCAPE=True
778     else
779       SOCAT_USE_ESCAPE=False
780     fi
781   ]])
782
783 if test -z "$SOCAT_USE_ESCAPE"
784 then
785   if $SOCAT -hh | grep -w -q escape; then
786     SOCAT_USE_ESCAPE=True
787   else
788     SOCAT_USE_ESCAPE=False
789   fi
790 fi
791
792 AC_SUBST(SOCAT_USE_ESCAPE)
793
794 SOCAT_USE_COMPRESS=
795 AC_ARG_ENABLE([socat-compress],
796   [AS_HELP_STRING([--enable-socat-compress],
797     [use OpenSSL compression option available in patched socat builds
798      (see INSTALL for details; default: detect automatically)])],
799   [[if test "$enableval" = yes; then
800       SOCAT_USE_COMPRESS=True
801     else
802       SOCAT_USE_COMPRESS=False
803     fi
804   ]])
805
806 if test -z "$SOCAT_USE_COMPRESS"
807 then
808   if $SOCAT -hhh | grep -w -q openssl-compress; then
809     SOCAT_USE_COMPRESS=True
810   else
811     SOCAT_USE_COMPRESS=False
812   fi
813 fi
814
815 AC_SUBST(SOCAT_USE_COMPRESS)
816
817 if man --help | grep -q -e --warnings
818 then
819   MAN_HAS_WARNINGS=1
820 else
821   MAN_HAS_WARNINGS=
822   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
823                             will not be possible]))
824 fi
825
826 AC_SUBST(MAN_HAS_WARNINGS)
827
828 # Check for Python
829 AM_PATH_PYTHON(2.6)
830
831 AC_PYTHON_MODULE(OpenSSL, t)
832 AC_PYTHON_MODULE(simplejson, t)
833 AC_PYTHON_MODULE(pyparsing, t)
834 AC_PYTHON_MODULE(pyinotify, t)
835 AC_PYTHON_MODULE(pycurl, t)
836 AC_PYTHON_MODULE(bitarray, t)
837 AC_PYTHON_MODULE(ipaddr, t)
838 AC_PYTHON_MODULE(mock)
839 AC_PYTHON_MODULE(affinity)
840 AC_PYTHON_MODULE(paramiko)
841
842 # Development-only Python modules
843 PY_NODEV=
844 AC_PYTHON_MODULE(yaml)
845 if test $HAVE_PYMOD_YAML == "no"; then
846   PY_NODEV="$PY_NODEV yaml"
847 fi
848
849 if test -n "$PY_NODEV"; then
850   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
851                             found, you won't be able to run Python unittests]))
852 else
853   AC_MSG_NOTICE([Python development modules found, unittests enabled])
854 fi
855 AC_SUBST(PY_NODEV)
856 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
857
858 include_makefile_ghc='
859 ifneq ($(MAKECMDGOALS),ganeti)
860 ifneq ($(MAKECMDGOALS),clean)
861 ifneq ($(MAKECMDGOALS),distclean)
862 include Makefile.ghc
863 endif
864 endif
865 endif
866 '
867 AC_SUBST([include_makefile_ghc])
868 AM_SUBST_NOTMAKE([include_makefile_ghc])
869
870 AC_CONFIG_FILES([ Makefile ])
871
872 AC_OUTPUT