cf58e397eb045161b815c14c68841d766fbdb0dd
[ganeti-github.git] / configure.ac
1 # Configure script for Ganeti
2 m4_define([gnt_version_major], [2])
3 m4_define([gnt_version_minor], [15])
4 m4_define([gnt_version_revision], [0])
5 m4_define([gnt_version_suffix], [~rc1])
6 m4_define([gnt_version_full],
7           m4_format([%d.%d.%d%s],
8                     gnt_version_major, gnt_version_minor,
9                     gnt_version_revision, gnt_version_suffix))
10
11 AC_PREREQ(2.59)
12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
13 AC_CONFIG_AUX_DIR(autotools)
14 AC_CONFIG_SRCDIR(configure)
15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability]
16                  m4_esyscmd([case `automake --version | head -n 1` in
17                              *1.11*);;
18                              *) echo serial-tests;;
19                              esac]))
20
21 AC_SUBST([VERSION_MAJOR], gnt_version_major)
22 AC_SUBST([VERSION_MINOR], gnt_version_minor)
23 AC_SUBST([VERSION_REVISION], gnt_version_revision)
24 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
25 AC_SUBST([VERSION_FULL], gnt_version_full)
26
27 AC_SUBST([BINDIR], $bindir)
28 AC_SUBST([SBINDIR], $sbindir)
29 AC_SUBST([MANDIR], $mandir)
30
31 # --enable-versionfull
32 AC_ARG_ENABLE([versionfull],
33   [AS_HELP_STRING([--enable-versionfull],
34                   m4_normalize([use the full version string rather
35                   than major.minor for version directories]))],
36   [[if test "$enableval" != no; then
37       USE_VERSION_FULL=yes
38     else
39       USER_VERSION_FULL=no
40     fi
41   ]],
42   [USE_VERSION_FULL=no
43   ])
44 AC_SUBST(USE_VERSION_FULL, $USE_VERSION_FULL)
45 AM_CONDITIONAL([USE_VERSION_FULL], [test "$USE_VERSION_FULL" = yes])
46
47 # --enable-symlinks
48 AC_ARG_ENABLE([symlinks],
49   [AS_HELP_STRING([--enable-symlinks],
50                   m4_normalize([also install version-dependent symlinks under
51                   $sysconfdir (default: disabled)]))],
52   [[if test "$enableval" != yes; then
53       INSTALL_SYMLINKS=no
54     else
55       INSTALL_SYMLINKS=yes
56     fi
57   ]],
58   [INSTALL_SYMLINKS=no
59   ])
60 AC_SUBST(INSTALL_SYMLINKS, $INSTALL_SYMLINKS)
61 AM_CONDITIONAL([INSTALL_SYMLINKS], [test "$INSTALL_SYMLINKS" = yes])
62
63 # --enable-haskell-profiling
64 AC_ARG_ENABLE([haskell-profiling],
65   [AS_HELP_STRING([--enable-haskell-profiling],
66                   m4_normalize([enable profiling for Haskell binaries
67                   (default: disabled)]))],
68   [[if test "$enableval" != yes; then
69       HPROFILE=no
70     else
71       HPROFILE=yes
72     fi
73   ]],
74   [HPROFILE=no
75   ])
76 AC_SUBST(HPROFILE, $HPROFILE)
77 AM_CONDITIONAL([HPROFILE], [test "$HPROFILE" = yes])
78
79 # --enable-haskell-coverage
80 AC_ARG_ENABLE([haskell-coverage],
81   [AS_HELP_STRING([--enable-haskell-coverage],
82                   m4_normalize([enable coverage for Haskell binaries
83                   (default: disabled)]))],
84   [[if test "$enableval" != yes; then
85       HCOVERAGE=no
86     else
87       HCOVERAGE=yes
88     fi
89   ]],
90   [HCOVERAGE=no
91   ])
92 AC_SUBST(HCOVERAGE, $HCOVERAGE)
93 AM_CONDITIONAL([HCOVERAGE], [test "$HCOVERAGE" = yes])
94
95 # --enable-haskell-tests
96 AC_ARG_ENABLE([haskell-tests],
97   [AS_HELP_STRING([--enable-haskell-tests],
98                   m4_normalize([enable additinal Haskell development test code
99                   (default: disabled)]))],
100   [[if test "$enableval" != yes; then
101       HTEST=no
102     else
103       HTEST=yes
104     fi
105   ]],
106   [HTEST=no
107   ])
108 AC_SUBST(HTEST, $HTEST)
109 AM_CONDITIONAL([HTEST], [test "$HTEST" = yes])
110
111 # --enable-developer-mode
112 AC_ARG_ENABLE([developer-mode],
113   [AS_HELP_STRING([--enable-developer-mode],
114                   m4_normalize([do a developper build with additional
115                   checks and fatal warnings; this is implied by enabling
116                   the haskell tests]))],
117   [[if test "$enableval" != no; then
118       DEVELOPER_MODE=yes
119     else
120       DEVELOPER_MODE=no
121     fi
122   ]],
123   [DEVELOPER_MODE=no
124   ])
125 AC_SUBST(DEVELOPER_MODE, $DEVELOPER_MODE)
126 AM_CONDITIONAL([DEVELOPER_MODE],
127                [test "$DEVELOPER_MODE" = yes -o "$HTEST" = yes])
128
129 # --with-haskell-flags=
130 AC_ARG_WITH([haskell-flags],
131   [AS_HELP_STRING([--with-haskell-flags=FLAGS],
132     [Extra flags to pass to GHC]
133   )],
134   [hextra_configure="$withval"],
135   [hextra_configure=""])
136 AC_SUBST(HEXTRA_CONFIGURE, $hextra_configure)
137
138 # --with-ssh-initscript=...
139 AC_ARG_WITH([ssh-initscript],
140   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
141     [SSH init script to use (default is /etc/init.d/ssh)]
142   )],
143   [ssh_initd_script="$withval"],
144   [ssh_initd_script="/etc/init.d/ssh"])
145 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
146
147 # --with-export-dir=...
148 AC_ARG_WITH([export-dir],
149   [AS_HELP_STRING([--with-export-dir=DIR],
150     [directory to use by default for instance image]
151     [ exports (default is /srv/ganeti/export)]
152   )],
153   [export_dir="$withval"],
154   [export_dir="/srv/ganeti/export"])
155 AC_SUBST(EXPORT_DIR, $export_dir)
156
157 # --with-backup-dir=...
158 AC_ARG_WITH([backup-dir],
159   [AS_HELP_STRING([--with-backup-dir=DIR],
160     [directory to use for configuration backups]
161     [ on Ganeti upgrades (default is $(localstatedir)/lib)]
162   )],
163   [backup_dir="$withval"
164    USE_BACKUP_DIR=yes
165   ],
166   [backup_dir=
167    USE_BACKUP_DIR=no
168   ])
169 AC_SUBST(BACKUP_DIR, $backup_dir)
170 AM_CONDITIONAL([USE_BACKUP_DIR], [test "$USE_BACKUP_DIR" = yes])
171
172 # --with-ssh-config-dir=...
173 AC_ARG_WITH([ssh-config-dir],
174   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
175     [ directory with ssh host keys ]
176     [ (default is /etc/ssh)]
177   )],
178   [ssh_config_dir="$withval"],
179   [ssh_config_dir="/etc/ssh"])
180 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
181
182 # --with-xen-config-dir=...
183 AC_ARG_WITH([xen-config-dir],
184   [AS_HELP_STRING([--with-xen-config-dir=DIR],
185                   m4_normalize([Xen configuration directory
186                                 (default: /etc/xen)]))],
187   [xen_config_dir="$withval"],
188   [xen_config_dir=/etc/xen])
189 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
190
191 # --with-os-search-path=...
192 AC_ARG_WITH([os-search-path],
193   [AS_HELP_STRING([--with-os-search-path=LIST],
194     [comma separated list of directories to]
195     [ search for OS images (default is /srv/ganeti/os)]
196   )],
197   [os_search_path="$withval"],
198   [os_search_path="/srv/ganeti/os"])
199 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
200
201 # --with-extstorage-search-path=...
202 AC_ARG_WITH([extstorage-search-path],
203   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
204     [comma separated list of directories to]
205     [ search for External Storage Providers]
206     [ (default is /srv/ganeti/extstorage)]
207   )],
208   [es_search_path="$withval"],
209   [es_search_path="/srv/ganeti/extstorage"])
210 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
211
212 # --with-iallocator-search-path=...
213 AC_ARG_WITH([iallocator-search-path],
214   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
215     [comma separated list of directories to]
216     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
217   )],
218   [iallocator_search_path="$withval"],
219   [iallocator_search_path="$libdir/$PACKAGE_NAME/iallocators"])
220 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
221
222 # --with-default-vg=...
223 AC_ARG_WITH([default-vg],
224   [AS_HELP_STRING([--with-default-vg=VOLUMEGROUP],
225     [default volume group (default is xenvg)]
226   )],
227   [default_vg="$withval"],
228   [default_vg="xenvg"])
229 AC_SUBST(DEFAULT_VG, $default_vg)
230
231 # --with-default-bridge=...
232 AC_ARG_WITH([default-bridge],
233   [AS_HELP_STRING([--with-default-bridge=BRIDGE],
234     [default bridge (default is xen-br0)]
235   )],
236   [default_bridge="$withval"],
237   [default_bridge="xen-br0"])
238 AC_SUBST(DEFAULT_BRIDGE, $default_bridge)
239
240 # --with-xen-bootloader=...
241 AC_ARG_WITH([xen-bootloader],
242   [AS_HELP_STRING([--with-xen-bootloader=PATH],
243     [bootloader for Xen hypervisor (default is empty)]
244   )],
245   [xen_bootloader="$withval"],
246   [xen_bootloader=])
247 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
248
249 # --with-xen-kernel=...
250 AC_ARG_WITH([xen-kernel],
251   [AS_HELP_STRING([--with-xen-kernel=PATH],
252     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
253   )],
254   [xen_kernel="$withval"],
255   [xen_kernel="/boot/vmlinuz-3-xenU"])
256 AC_SUBST(XEN_KERNEL, $xen_kernel)
257
258 # --with-xen-initrd=...
259 AC_ARG_WITH([xen-initrd],
260   [AS_HELP_STRING([--with-xen-initrd=PATH],
261     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
262   )],
263   [xen_initrd="$withval"],
264   [xen_initrd="/boot/initrd-3-xenU"])
265 AC_SUBST(XEN_INITRD, $xen_initrd)
266
267 # --with-kvm-kernel=...
268 AC_ARG_WITH([kvm-kernel],
269   [AS_HELP_STRING([--with-kvm-kernel=PATH],
270     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
271   )],
272   [kvm_kernel="$withval"],
273   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
274 AC_SUBST(KVM_KERNEL, $kvm_kernel)
275
276 # --with-kvm-path=...
277 AC_ARG_WITH([kvm-path],
278   [AS_HELP_STRING([--with-kvm-path=PATH],
279     [absolute path to the kvm binary]
280     [ (default is /usr/bin/kvm)]
281   )],
282   [kvm_path="$withval"],
283   [kvm_path="/usr/bin/kvm"])
284 AC_SUBST(KVM_PATH, $kvm_path)
285
286 # --with-lvm-stripecount=...
287 AC_ARG_WITH([lvm-stripecount],
288   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
289     [the default number of stripes to use for LVM volumes]
290     [ (default is 1)]
291   )],
292   [lvm_stripecount="$withval"],
293   [lvm_stripecount=1])
294 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
295
296 # --with-ssh-login-user=...
297 AC_ARG_WITH([ssh-login-user],
298   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
299     [user to use for SSH logins within the cluster (default is root)]
300   )],
301   [ssh_login_user="$withval"],
302   [ssh_login_user=root])
303 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
304
305 # --with-ssh-console-user=...
306 AC_ARG_WITH([ssh-console-user],
307   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
308     [user to use for SSH logins to access instance consoles (default is root)]
309   )],
310   [ssh_console_user="$withval"],
311   [ssh_console_user=root])
312 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
313
314 # --with-default-user=...
315 AC_ARG_WITH([default-user],
316   [AS_HELP_STRING([--with-default-user=USERNAME],
317     [default user for daemons]
318     [ (default is to run all daemons as root)]
319   )],
320   [user_default="$withval"],
321   [user_default=root])
322
323 # --with-default-group=...
324 AC_ARG_WITH([default-group],
325   [AS_HELP_STRING([--with-default-group=GROUPNAME],
326     [default group for daemons]
327     [ (default is to run all daemons under group root)]
328   )],
329   [group_default="$withval"],
330   [group_default=root])
331
332 # --with-user-prefix=...
333 AC_ARG_WITH([user-prefix],
334   [AS_HELP_STRING([--with-user-prefix=PREFIX],
335     [prefix for daemon users]
336     [ (default is to run all daemons as root; use --with-default-user]
337     [ to change the default)]
338   )],
339   [user_masterd="${withval}masterd";
340    user_metad="$user_default";
341    user_rapi="${withval}rapi";
342    user_confd="${withval}confd";
343    user_wconfd="${withval}masterd";
344    user_kvmd="$user_default";
345    user_luxid="${withval}masterd";
346    user_noded="$user_default";
347    user_mond="$user_default"],
348   [user_masterd="$user_default";
349    user_metad="$user_default";
350    user_rapi="$user_default";
351    user_confd="$user_default";
352    user_wconfd="$user_default";
353    user_kvmd="$user_default";
354    user_luxid="$user_default";
355    user_noded="$user_default";
356    user_mond="$user_default"])
357 AC_SUBST(MASTERD_USER, $user_masterd)
358 AC_SUBST(METAD_USER, $user_metad)
359 AC_SUBST(RAPI_USER, $user_rapi)
360 AC_SUBST(CONFD_USER, $user_confd)
361 AC_SUBST(WCONFD_USER, $user_wconfd)
362 AC_SUBST(KVMD_USER, $user_kvmd)
363 AC_SUBST(LUXID_USER, $user_luxid)
364 AC_SUBST(NODED_USER, $user_noded)
365 AC_SUBST(MOND_USER, $user_mond)
366
367 # --with-group-prefix=...
368 AC_ARG_WITH([group-prefix],
369   [AS_HELP_STRING([--with-group-prefix=PREFIX],
370     [prefix for daemon POSIX groups]
371     [ (default is to run all daemons under group root; use]
372     [ --with-default-group to change the default)]
373   )],
374   [group_rapi="${withval}rapi";
375    group_admin="${withval}admin";
376    group_confd="${withval}confd";
377    group_wconfd="${withval}masterd";
378    group_kvmd="$group_default";
379    group_luxid="${withval}luxid";
380    group_masterd="${withval}masterd";
381    group_metad="$group_default";
382    group_noded="$group_default";
383    group_daemons="${withval}daemons";
384    group_mond="$group_default"],
385   [group_rapi="$group_default";
386    group_admin="$group_default";
387    group_confd="$group_default";
388    group_wconfd="$group_default";
389    group_kvmd="$group_default";
390    group_luxid="$group_default";
391    group_masterd="$group_default";
392    group_metad="$group_default";
393    group_noded="$group_default";
394    group_daemons="$group_default";
395    group_mond="$group_default"])
396 AC_SUBST(RAPI_GROUP, $group_rapi)
397 AC_SUBST(ADMIN_GROUP, $group_admin)
398 AC_SUBST(CONFD_GROUP, $group_confd)
399 AC_SUBST(WCONFD_GROUP, $group_wconfd)
400 AC_SUBST(KVMD_GROUP, $group_kvmd)
401 AC_SUBST(LUXID_GROUP, $group_luxid)
402 AC_SUBST(MASTERD_GROUP, $group_masterd)
403 AC_SUBST(METAD_GROUP, $group_metad)
404 AC_SUBST(NODED_GROUP, $group_noded)
405 AC_SUBST(DAEMONS_GROUP, $group_daemons)
406 AC_SUBST(MOND_GROUP, $group_mond)
407
408 # Print the config to the user
409 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
410 AC_MSG_NOTICE([Running ganeti-metad as $group_metad:$group_metad])
411 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
412 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
413 AC_MSG_NOTICE([Running ganeti-wconfd as $user_wconfd:$group_wconfd])
414 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
415 AC_MSG_NOTICE([Group for daemons is $group_daemons])
416 AC_MSG_NOTICE([Group for clients is $group_admin])
417
418 # --enable-drbd-barriers
419 AC_ARG_ENABLE([drbd-barriers],
420   [AS_HELP_STRING([--enable-drbd-barriers],
421                   m4_normalize([enable the DRBD barriers functionality by
422                                 default (>= 8.0.12) (default: enabled)]))],
423   [[if test "$enableval" != no; then
424       DRBD_BARRIERS=n
425       DRBD_NO_META_FLUSH=False
426     else
427       DRBD_BARRIERS=bf
428       DRBD_NO_META_FLUSH=True
429     fi
430   ]],
431   [DRBD_BARRIERS=n
432    DRBD_NO_META_FLUSH=False
433   ])
434 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
435 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
436
437 # --enable-syslog[=no/yes/only]
438 AC_ARG_ENABLE([syslog],
439   [AS_HELP_STRING([--enable-syslog],
440     [enable use of syslog (default: disabled), one of no/yes/only])],
441   [[case "$enableval" in
442       no)
443         SYSLOG=no
444         ;;
445       yes)
446         SYSLOG=yes
447         ;;
448       only)
449         SYSLOG=only
450         ;;
451       *)
452         SYSLOG=
453         ;;
454     esac
455   ]],
456   [SYSLOG=no])
457
458 if test -z "$SYSLOG"
459 then
460   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
461 fi
462 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
463
464 # --enable-restricted-commands[=no/yes]
465 AC_ARG_ENABLE([restricted-commands],
466   [AS_HELP_STRING([--enable-restricted-commands],
467                   m4_normalize([enable restricted commands in the node daemon
468                                 (default: disabled)]))],
469   [[if test "$enableval" = no; then
470       enable_restricted_commands=False
471     else
472       enable_restricted_commands=True
473     fi
474   ]],
475   [enable_restricted_commands=False])
476 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
477
478 # --with-disk-separator=...
479 AC_ARG_WITH([disk-separator],
480   [AS_HELP_STRING([--with-disk-separator=STRING],
481     [Disk index separator, useful if the default of ':' is handled]
482     [ specially by the hypervisor]
483   )],
484   [disk_separator="$withval"],
485   [disk_separator=":"])
486 AC_SUBST(DISK_SEPARATOR, $disk_separator)
487
488 # Check common programs
489 AC_PROG_INSTALL
490 AC_PROG_LN_S
491
492 # check if ln is the GNU version of ln (and hence supports -T)
493 if ln --version 2> /dev/null | head -1 | grep -q GNU
494 then
495   AC_SUBST(HAS_GNU_LN, True)
496 else
497   AC_SUBST(HAS_GNU_LN, False)
498 fi
499
500 # Check for the ip command
501 AC_ARG_VAR(IP_PATH, [ip path])
502 AC_PATH_PROG(IP_PATH, [ip], [])
503 if test -z "$IP_PATH"
504 then
505   AC_MSG_ERROR([ip command not found])
506 fi
507
508 # Check for pandoc
509 AC_ARG_VAR(PANDOC, [pandoc path])
510 AC_PATH_PROG(PANDOC, [pandoc], [])
511 if test -z "$PANDOC"
512 then
513   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
514 fi
515
516 # Check for python-sphinx
517 AC_ARG_VAR(SPHINX, [sphinx-build path])
518 AC_PATH_PROG(SPHINX, [sphinx-build], [])
519 if test -z "$SPHINX"
520 then
521   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
522                             not be possible]))
523 else
524   # Sphinx exits with code 1 when it prints its usage
525   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
526
527   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
528     AC_MSG_ERROR([Unable to determine Sphinx version])
529
530   # Note: Character classes ([...]) need to be double quoted due to autoconf
531   # using m4
532   elif ! echo "$sphinxver" | grep -q -E \
533        '^Sphinx([[[:space:]]]+|\(sphinx-build[[1-9]]?\)|v)*[[1-9]]\>'; then
534     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
535   fi
536 fi
537 AM_CONDITIONAL([HAS_SPHINX], [test -n "$SPHINX"])
538 AM_CONDITIONAL([HAS_SPHINX_PRE13],
539  [test -n "$SPHINX" && echo "$sphinxver" | grep -q -E \
540   '^Sphinx([[[:space:]]]+|\(sphinx-build[[1-9]]?\)|v)*[[1-9]]\.[[0-2]]\.'])
541
542 AC_ARG_ENABLE([manpages-in-doc],
543   [AS_HELP_STRING([--enable-manpages-in-doc],
544                   m4_normalize([include man pages in HTML documentation
545                                 (requires sphinx; default disabled)]))],
546   [case "$enableval" in
547       yes) manpages_in_doc=yes ;;
548       no) manpages_in_doc= ;;
549       *)
550         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
551         ;;
552     esac
553   ],
554   [manpages_in_doc=])
555 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
556 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
557
558 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
559   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
560 fi
561
562 # Check for graphviz (dot)
563 AC_ARG_VAR(DOT, [dot path])
564 AC_PATH_PROG(DOT, [dot], [])
565 if test -z "$DOT"
566 then
567   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
568                             documentation rebuild not possible]))
569 fi
570
571 # Check for pylint
572 AC_ARG_VAR(PYLINT, [pylint path])
573 AC_PATH_PROG(PYLINT, [pylint], [])
574 if test -z "$PYLINT"
575 then
576   AC_MSG_WARN([pylint not found, checking code will not be possible])
577 fi
578
579 # Check for pep8
580 AC_ARG_VAR(PEP8, [pep8 path])
581 AC_PATH_PROG(PEP8, [pep8], [])
582 if test -z "$PEP8"
583 then
584   AC_MSG_WARN([pep8 not found, checking code will not be complete])
585 fi
586 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
587
588 # Check for python-coverage
589 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
590 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
591 if test -z "$PYCOVERAGE"
592 then
593   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
594                             Python test coverage will not be possible]))
595 fi
596
597 # Check for socat
598 AC_ARG_VAR(SOCAT, [socat path])
599 AC_PATH_PROG(SOCAT, [socat], [])
600 if test -z "$SOCAT"
601 then
602   AC_MSG_ERROR([socat not found])
603 fi
604
605 # Check for qemu-img
606 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
607 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
608 if test -z "$QEMUIMG_PATH"
609 then
610   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
611 fi
612
613 ENABLE_MOND=
614 AC_ARG_ENABLE([monitoring],
615   [AS_HELP_STRING([--enable-monitoring],
616   [enable the ganeti monitoring daemon (default: check)])],
617   [],
618   [enable_monitoring=check])
619
620 # --enable-metadata
621 ENABLE_METADATA=
622 AC_ARG_ENABLE([metadata],
623   [AS_HELP_STRING([--enable-metadata],
624   [enable the ganeti metadata daemon (default: check)])],
625   [],
626   [enable_metadata=check])
627
628 # Check for ghc
629 AC_ARG_VAR(GHC, [ghc path])
630 AC_PATH_PROG(GHC, [ghc], [])
631 if test -z "$GHC"; then
632   AC_MSG_FAILURE([ghc not found, compilation will not possible])
633 fi
634
635 # Note: Character classes ([...]) need to be double quoted due to autoconf
636 # using m4
637 AM_CONDITIONAL([GHC_LE_76], [$GHC --numeric-version | grep -q '^7\.[[0-6]]\.'])
638
639 AC_MSG_CHECKING([checking for extra GHC flags])
640 GHC_BYVERSION_FLAGS=
641 # check for GHC supported flags that vary accross versions
642 for flag in -fwarn-incomplete-uni-patterns; do
643   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
644    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
645   fi
646 done
647 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
648 AC_SUBST(GHC_BYVERSION_FLAGS)
649
650 # Check for ghc-pkg
651 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
652 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
653 if test -z "$GHC_PKG"; then
654   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
655 fi
656
657 # Check for cabal
658 AC_ARG_VAR(CABAL, [cabal path])
659 AC_PATH_PROG(CABAL, [cabal], [])
660 if test -z "$CABAL"; then
661   AC_MSG_FAILURE([cabal not found, compilation will not be possible])
662 fi
663
664 # check for standard modules
665 AC_GHC_PKG_REQUIRE(Cabal)
666 AC_GHC_PKG_REQUIRE(curl)
667 AC_GHC_PKG_REQUIRE(json)
668 AC_GHC_PKG_REQUIRE(network)
669 AC_GHC_PKG_REQUIRE(mtl)
670 AC_GHC_PKG_REQUIRE(bytestring)
671 AC_GHC_PKG_REQUIRE(base64-bytestring-1.*, t)
672 AC_GHC_PKG_REQUIRE(utf8-string)
673 AC_GHC_PKG_REQUIRE(zlib)
674 AC_GHC_PKG_REQUIRE(hslogger)
675 AC_GHC_PKG_REQUIRE(process)
676 AC_GHC_PKG_REQUIRE(attoparsec)
677 AC_GHC_PKG_REQUIRE(vector)
678 AC_GHC_PKG_REQUIRE(text)
679 AC_GHC_PKG_REQUIRE(hinotify)
680 AC_GHC_PKG_REQUIRE(Crypto)
681 AC_GHC_PKG_REQUIRE(lifted-base)
682 AC_GHC_PKG_REQUIRE(lens)
683 AC_GHC_PKG_REQUIRE(regex-pcre)
684
685 #extra modules for monitoring daemon functionality; also needed for tests
686 MONITORING_PKG=
687 AC_GHC_PKG_CHECK([snap-server], [],
688                  [NS_NODEV=1; MONITORING_PKG="$MONITORING_PKG snap-server"])
689 AC_GHC_PKG_CHECK([PSQueue], [],
690                  [NS_NODEV=1; MONITORING_PKG="$MONITORING_PKG PSQueue"])
691
692 has_monitoring=False
693 if test "$enable_monitoring" != no; then
694   MONITORING_DEP=
695   has_monitoring_pkg=False
696   if test -z "$MONITORING_PKG"; then
697     has_monitoring_pkg=True
698   elif test "$enable_monitoring" = check; then
699     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
700                               daemon were not found ($MONITORING_PKG),
701                               monitoring disabled]))
702   else
703     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
704                                  required libraries were not found:
705                                  $MONITORING_PKG]))
706   fi
707   has_monitoring_dep=False
708   if test -z "$MONITORING_DEP"; then
709     has_monitoring_dep=True
710   elif test "$enable_monitoring" = check; then
711     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
712                               monitoring agent were not enabled
713                               ($MONITORING_DEP), monitoring disabled]))
714   else
715     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
716                                  required optional Ganeti components were not
717                                  found: $MONITORING_DEP]))
718   fi
719
720 fi
721 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
722   has_monitoring=True
723   AC_MSG_NOTICE([Enabling the monitoring agent usage])
724 fi
725 AC_SUBST(ENABLE_MOND, $has_monitoring)
726 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
727
728 # extra modules for metad functionality; also needed for tests
729 METAD_PKG=
730 AC_GHC_PKG_CHECK([snap-server], [],
731                  [NS_NODEV=1; METAD_PKG="$METAD_PKG snap-server"])
732 has_metad=False
733 if test "$enable_metadata" != no; then
734   if test -z "$METAD_PKG"; then
735     has_metad=True
736   elif test "$enable_metadata" = check; then
737     AC_MSG_WARN(m4_normalize([The required extra libraries for metad were
738                               not found ($METAD_PKG), metad disabled]))
739   else
740     AC_MSG_FAILURE(m4_normalize([The metadata functionality was requested, but
741                                  required libraries were not found:
742                                  $METAD_PKG]))
743   fi
744 fi
745 if test "$has_metad" = True; then
746   AC_MSG_NOTICE([Enabling metadata usage])
747 fi
748 AC_SUBST(ENABLE_METADATA, $has_metad)
749 AM_CONDITIONAL([ENABLE_METADATA], [test x$has_metad = xTrue])
750
751
752 # development modules
753 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
754 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [
755   AC_GHC_PKG_CHECK([test-framework-0.7*], [], [
756     AC_GHC_PKG_CHECK([test-framework-0.8*], [], [HS_NODEV=1], t)
757   ], t)
758 ], t)
759 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
760 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
761 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
762 if test -n "$HS_NODEV"; then
763    AC_MSG_WARN(m4_normalize([Required development modules were not found,
764                              you won't be able to run Haskell unittests]))
765 else
766    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
767 fi
768 AC_SUBST(HS_NODEV)
769 AM_CONDITIONAL([HS_UNIT], [test -n $HS_NODEV])
770
771 # Check for HsColour
772 HS_APIDOC=no
773 AC_ARG_VAR(HSCOLOUR, [HsColour path])
774 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
775 if test -z "$HSCOLOUR"; then
776   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
777                             not be generated]))
778 fi
779
780 # Check for haddock
781 AC_ARG_VAR(HADDOCK, [haddock path])
782 AC_PATH_PROG(HADDOCK, [haddock], [])
783 if test -z "$HADDOCK"; then
784   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
785                             not be generated]))
786 fi
787 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
788   HS_APIDOC=yes
789 fi
790 AC_SUBST(HS_APIDOC)
791
792 # Check for hlint
793 AC_ARG_VAR(HLINT, [hlint path])
794 AC_PATH_PROG(HLINT, [hlint], [])
795 if test -z "$HLINT"; then
796   AC_MSG_WARN([hlint not found, checking code will not be possible])
797 fi
798
799 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
800 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
801 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
802
803 # Check for fakeroot
804 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
805 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
806 if test -z "$FAKEROOT_PATH"; then
807   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
808                             will not be executed]))
809 fi
810 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
811
812 SOCAT_USE_ESCAPE=
813 AC_ARG_ENABLE([socat-escape],
814   [AS_HELP_STRING([--enable-socat-escape],
815     [use escape functionality available in socat >= 1.7 (default: detect
816      automatically)])],
817   [[if test "$enableval" = yes; then
818       SOCAT_USE_ESCAPE=True
819     else
820       SOCAT_USE_ESCAPE=False
821     fi
822   ]])
823
824 if test -z "$SOCAT_USE_ESCAPE"
825 then
826   if $SOCAT -hh | grep -w -q escape; then
827     SOCAT_USE_ESCAPE=True
828   else
829     SOCAT_USE_ESCAPE=False
830   fi
831 fi
832
833 AC_SUBST(SOCAT_USE_ESCAPE)
834
835 SOCAT_USE_COMPRESS=
836 AC_ARG_ENABLE([socat-compress],
837   [AS_HELP_STRING([--enable-socat-compress],
838     [use OpenSSL compression option available in patched socat builds
839      (see INSTALL for details; default: detect automatically)])],
840   [[if test "$enableval" = yes; then
841       SOCAT_USE_COMPRESS=True
842     else
843       SOCAT_USE_COMPRESS=False
844     fi
845   ]])
846
847 if test -z "$SOCAT_USE_COMPRESS"
848 then
849   if $SOCAT -hhh | grep -w -q openssl-compress; then
850     SOCAT_USE_COMPRESS=True
851   else
852     SOCAT_USE_COMPRESS=False
853   fi
854 fi
855
856 AC_SUBST(SOCAT_USE_COMPRESS)
857
858 if man --help | grep -q -e --warnings
859 then
860   MAN_HAS_WARNINGS=1
861 else
862   MAN_HAS_WARNINGS=
863   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
864                             will not be possible]))
865 fi
866
867 AC_SUBST(MAN_HAS_WARNINGS)
868
869 # Check for Python
870 AM_PATH_PYTHON(2.6)
871
872 AC_PYTHON_MODULE(OpenSSL, t)
873 AC_PYTHON_MODULE(simplejson, t)
874 AC_PYTHON_MODULE(pyparsing, t)
875 AC_PYTHON_MODULE(pyinotify, t)
876 AC_PYTHON_MODULE(pycurl, t)
877 AC_PYTHON_MODULE(bitarray, t)
878 AC_PYTHON_MODULE(ipaddr, t)
879 AC_PYTHON_MODULE(mock)
880 AC_PYTHON_MODULE(psutil)
881 AC_PYTHON_MODULE(paramiko)
882
883 # Development-only Python modules
884 PY_NODEV=
885 AC_PYTHON_MODULE(yaml)
886 if test $HAVE_PYMOD_YAML == "no"; then
887   PY_NODEV="$PY_NODEV yaml"
888 fi
889
890 if test -n "$PY_NODEV"; then
891   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
892                             found, you won't be able to run Python unittests]))
893 else
894   AC_MSG_NOTICE([Python development modules found, unittests enabled])
895 fi
896 AC_SUBST(PY_NODEV)
897 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
898
899 include_makefile_ghc='
900 ifneq ($(MAKECMDGOALS),ganeti)
901 ifneq ($(MAKECMDGOALS),clean)
902 ifneq ($(MAKECMDGOALS),distclean)
903 include Makefile.ghc
904 endif
905 endif
906 endif
907 '
908 AC_SUBST([include_makefile_ghc])
909 AM_SUBST_NOTMAKE([include_makefile_ghc])
910
911 AC_CONFIG_FILES([ Makefile ])
912
913 AC_OUTPUT