Disable python test if required libraries are missing
[ganeti-github.git] / configure.ac
1 # Configure script for Ganeti
2 m4_define([gnt_version_major], [2])
3 m4_define([gnt_version_minor], [8])
4 m4_define([gnt_version_revision], [0])
5 m4_define([gnt_version_suffix], [~alpha1])
6 m4_define([gnt_version_full],
7           m4_format([%d.%d.%d%s],
8                     gnt_version_major, gnt_version_minor,
9                     gnt_version_revision, gnt_version_suffix))
10
11 AC_PREREQ(2.59)
12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
13 AC_CONFIG_AUX_DIR(autotools)
14 AC_CONFIG_SRCDIR(configure)
15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
16
17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
21 AC_SUBST([VERSION_FULL], gnt_version_full)
22
23 # --with-ssh-initscript=...
24 AC_ARG_WITH([ssh-initscript],
25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
26     [SSH init script to use (default is /etc/init.d/ssh)]
27   )],
28   [ssh_initd_script="$withval"],
29   [ssh_initd_script="/etc/init.d/ssh"])
30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
31
32 # --with-export-dir=...
33 AC_ARG_WITH([export-dir],
34   [AS_HELP_STRING([--with-export-dir=DIR],
35     [directory to use by default for instance image]
36     [ exports (default is /srv/ganeti/export)]
37   )],
38   [export_dir="$withval"],
39   [export_dir="/srv/ganeti/export"])
40 AC_SUBST(EXPORT_DIR, $export_dir)
41
42 # --with-ssh-config-dir=...
43 AC_ARG_WITH([ssh-config-dir],
44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
45     [ directory with ssh host keys ]
46     [ (default is /etc/ssh)]
47   )],
48   [ssh_config_dir="$withval"],
49   [ssh_config_dir="/etc/ssh"])
50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
51
52 # --with-xen-config-dir=...
53 AC_ARG_WITH([xen-config-dir],
54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
55                   m4_normalize([Xen configuration directory
56                                 (default: /etc/xen)]))],
57   [xen_config_dir="$withval"],
58   [xen_config_dir=/etc/xen])
59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
60
61 # --with-os-search-path=...
62 # do a bit of black sed magic to for quoting of the strings in the list
63 AC_ARG_WITH([os-search-path],
64   [AS_HELP_STRING([--with-os-search-path=LIST],
65     [comma separated list of directories to]
66     [ search for OS images (default is /srv/ganeti/os)]
67   )],
68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
69   [os_search_path="'/srv/ganeti/os'"])
70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
71
72 # --with-extstorage-search-path=...
73 # same black sed magic for quoting of the strings in the list
74 AC_ARG_WITH([extstorage-search-path],
75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
76     [comma separated list of directories to]
77     [ search for External Storage Providers]
78     [ (default is /srv/ganeti/extstorage)]
79   )],
80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
81   [es_search_path="'/srv/ganeti/extstorage'"])
82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
83
84 # --with-iallocator-search-path=...
85 # do a bit of black sed magic to for quoting of the strings in the list
86 AC_ARG_WITH([iallocator-search-path],
87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
88     [comma separated list of directories to]
89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
90   )],
91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
94
95 # --with-xen-bootloader=...
96 AC_ARG_WITH([xen-bootloader],
97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
98     [bootloader for Xen hypervisor (default is empty)]
99   )],
100   [xen_bootloader="$withval"],
101   [xen_bootloader=])
102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
103
104 # --with-xen-kernel=...
105 AC_ARG_WITH([xen-kernel],
106   [AS_HELP_STRING([--with-xen-kernel=PATH],
107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
108   )],
109   [xen_kernel="$withval"],
110   [xen_kernel="/boot/vmlinuz-3-xenU"])
111 AC_SUBST(XEN_KERNEL, $xen_kernel)
112
113 # --with-xen-initrd=...
114 AC_ARG_WITH([xen-initrd],
115   [AS_HELP_STRING([--with-xen-initrd=PATH],
116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
117   )],
118   [xen_initrd="$withval"],
119   [xen_initrd="/boot/initrd-3-xenU"])
120 AC_SUBST(XEN_INITRD, $xen_initrd)
121
122 # --with-xen-cmd=...
123 AC_ARG_WITH([xen-cmd],
124   [AS_HELP_STRING([--with-xen-cmd=CMD],
125     [Sets the xen cli interface command (default is xm)]
126   )],
127   [xen_cmd="$withval"],
128   [xen_cmd=xm])
129 AC_SUBST(XEN_CMD, $xen_cmd)
130
131 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
132   AC_MSG_ERROR([Unsupported xen command specified])
133 fi
134
135 # --with-kvm-kernel=...
136 AC_ARG_WITH([kvm-kernel],
137   [AS_HELP_STRING([--with-kvm-kernel=PATH],
138     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
139   )],
140   [kvm_kernel="$withval"],
141   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
142 AC_SUBST(KVM_KERNEL, $kvm_kernel)
143
144 # --with-file-storage-dir=...
145 AC_ARG_WITH([file-storage-dir],
146   [AS_HELP_STRING([--with-file-storage-dir=PATH],
147     [directory to store files for file-based backend]
148     [ (default is /srv/ganeti/file-storage)]
149   )],
150   [[file_storage_dir="$withval";
151     if test "$withval" != no; then
152       enable_file_storage=True
153     else
154       enable_file_storage=False
155     fi
156   ]],
157   [[file_storage_dir="/srv/ganeti/file-storage";
158     enable_file_storage=True]])
159 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
160 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
161
162 # --with-shared-file-storage-dir=...
163 AC_ARG_WITH([shared-file-storage-dir],
164   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
165     [directory to store files for shared file-based backend]
166     [ (default is /srv/ganeti/shared-file-storage)]
167   )],
168   [[shared_file_storage_dir="$withval";
169     if test "$withval" != no; then
170       enable_shared_file_storage=True
171     else
172       enable_shared_file_storage=False
173     fi
174   ]],
175   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
176     enable_shared_file_storage=True]])
177 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
178 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
179
180 # --with-kvm-path=...
181 AC_ARG_WITH([kvm-path],
182   [AS_HELP_STRING([--with-kvm-path=PATH],
183     [absolute path to the kvm binary]
184     [ (default is /usr/bin/kvm)]
185   )],
186   [kvm_path="$withval"],
187   [kvm_path="/usr/bin/kvm"])
188 AC_SUBST(KVM_PATH, $kvm_path)
189
190 # --with-lvm-stripecount=...
191 AC_ARG_WITH([lvm-stripecount],
192   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
193     [the default number of stripes to use for LVM volumes]
194     [ (default is 1)]
195   )],
196   [lvm_stripecount="$withval"],
197   [lvm_stripecount=1])
198 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
199
200 # --with-ssh-login-user=...
201 AC_ARG_WITH([ssh-login-user],
202   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
203     [user to use for SSH logins within the cluster (default is root)]
204   )],
205   [ssh_login_user="$withval"],
206   [ssh_login_user=root])
207 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
208
209 # --with-ssh-console-user=...
210 AC_ARG_WITH([ssh-console-user],
211   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
212     [user to use for SSH logins to access instance consoles (default is root)]
213   )],
214   [ssh_console_user="$withval"],
215   [ssh_console_user=root])
216 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
217
218 # --with-default-user=...
219 AC_ARG_WITH([default-user],
220   [AS_HELP_STRING([--with-default-user=USERNAME],
221     [default user for daemons]
222     [ (default is to run all daemons as root)]
223   )],
224   [user_default="$withval"],
225   [user_default=root])
226
227 # --with-default-group=...
228 AC_ARG_WITH([default-group],
229   [AS_HELP_STRING([--with-default-group=GROUPNAME],
230     [default group for daemons]
231     [ (default is to run all daemons under group root)]
232   )],
233   [group_default="$withval"],
234   [group_default=root])
235
236 # --with-user-prefix=...
237 AC_ARG_WITH([user-prefix],
238   [AS_HELP_STRING([--with-user-prefix=PREFIX],
239     [prefix for daemon users]
240     [ (default is to run all daemons as root; use --with-default-user]
241     [ to change the default)]
242   )],
243   [user_masterd="${withval}masterd";
244    user_rapi="${withval}rapi";
245    user_confd="${withval}confd";
246    user_noded="$user_default";
247    user_mond="${withval}mond"],
248   [user_masterd="$user_default";
249    user_rapi="$user_default";
250    user_confd="$user_default";
251    user_noded="$user_default";
252    user_mond="$user_default"])
253 AC_SUBST(MASTERD_USER, $user_masterd)
254 AC_SUBST(RAPI_USER, $user_rapi)
255 AC_SUBST(CONFD_USER, $user_confd)
256 AC_SUBST(NODED_USER, $user_noded)
257 AC_SUBST(MOND_USER, $user_mond)
258
259 # --with-group-prefix=...
260 AC_ARG_WITH([group-prefix],
261   [AS_HELP_STRING([--with-group-prefix=PREFIX],
262     [prefix for daemon POSIX groups]
263     [ (default is to run all daemons under group root; use]
264     [ --with-default-group to change the default)]
265   )],
266   [group_rapi="${withval}rapi";
267    group_admin="${withval}admin";
268    group_confd="${withval}confd";
269    group_masterd="${withval}masterd";
270    group_noded="$group_default";
271    group_daemons="${withval}daemons";
272    group_mond="${withval}mond"],
273   [group_rapi="$group_default";
274    group_admin="$group_default";
275    group_confd="$group_default";
276    group_masterd="$group_default";
277    group_noded="$group_default";
278    group_daemons="$group_default";
279    group_mond="$group_default"])
280 AC_SUBST(RAPI_GROUP, $group_rapi)
281 AC_SUBST(ADMIN_GROUP, $group_admin)
282 AC_SUBST(CONFD_GROUP, $group_confd)
283 AC_SUBST(MASTERD_GROUP, $group_masterd)
284 AC_SUBST(NODED_GROUP, $group_noded)
285 AC_SUBST(DAEMONS_GROUP, $group_daemons)
286 AC_SUBST(MOND_GROUP, $group_mond)
287
288 # Print the config to the user
289 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
290 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
291 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
292 AC_MSG_NOTICE([Group for daemons is $group_daemons])
293 AC_MSG_NOTICE([Group for clients is $group_admin])
294
295 # --enable-drbd-barriers
296 AC_ARG_ENABLE([drbd-barriers],
297   [AS_HELP_STRING([--enable-drbd-barriers],
298                   m4_normalize([enable the DRBD barriers functionality by
299                                 default (>= 8.0.12) (default: enabled)]))],
300   [[if test "$enableval" != no; then
301       DRBD_BARRIERS=n
302       DRBD_NO_META_FLUSH=False
303     else
304       DRBD_BARRIERS=bf
305       DRBD_NO_META_FLUSH=True
306     fi
307   ]],
308   [DRBD_BARRIERS=n
309    DRBD_NO_META_FLUSH=False
310   ])
311 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
312 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
313
314 # --enable-syslog[=no/yes/only]
315 AC_ARG_ENABLE([syslog],
316   [AS_HELP_STRING([--enable-syslog],
317     [enable use of syslog (default: disabled), one of no/yes/only])],
318   [[case "$enableval" in
319       no)
320         SYSLOG=no
321         ;;
322       yes)
323         SYSLOG=yes
324         ;;
325       only)
326         SYSLOG=only
327         ;;
328       *)
329         SYSLOG=
330         ;;
331     esac
332   ]],
333   [SYSLOG=no])
334
335 if test -z "$SYSLOG"
336 then
337   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
338 fi
339 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
340
341 AC_ARG_ENABLE([restricted-commands],
342   [AS_HELP_STRING([--enable-restricted-commands],
343                   m4_normalize([enable restricted commands in the node daemon
344                                 (default: disabled)]))],
345   [[if test "$enableval" = no; then
346       enable_restricted_commands=False
347     else
348       enable_restricted_commands=True
349     fi
350   ]],
351   [enable_restricted_commands=False])
352 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
353
354 # --with-disk-separator=...
355 AC_ARG_WITH([disk-separator],
356   [AS_HELP_STRING([--with-disk-separator=STRING],
357     [Disk index separator, useful if the default of ':' is handled]
358     [ specially by the hypervisor]
359   )],
360   [disk_separator="$withval"],
361   [disk_separator=":"])
362 AC_SUBST(DISK_SEPARATOR, $disk_separator)
363
364 # Check common programs
365 AC_PROG_INSTALL
366 AC_PROG_LN_S
367
368 # Check for the ip command
369 AC_ARG_VAR(IP_PATH, [ip path])
370 AC_PATH_PROG(IP_PATH, [ip], [])
371 if test -z "$IP_PATH"
372 then
373   AC_MSG_ERROR([ip command not found])
374 fi
375
376 # Check for pandoc
377 AC_ARG_VAR(PANDOC, [pandoc path])
378 AC_PATH_PROG(PANDOC, [pandoc], [])
379 if test -z "$PANDOC"
380 then
381   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
382 fi
383
384 # Check for python-sphinx
385 AC_ARG_VAR(SPHINX, [sphinx-build path])
386 AC_PATH_PROG(SPHINX, [sphinx-build], [])
387 if test -z "$SPHINX"
388 then
389   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
390                             not be possible]))
391 else
392   # Sphinx exits with code 1 when it prints its usage
393   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
394
395   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
396     AC_MSG_ERROR([Unable to determine Sphinx version])
397
398   # Note: Character classes ([...]) need to be double quoted due to autoconf
399   # using m4
400   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
401     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
402   fi
403 fi
404
405 AC_ARG_ENABLE([manpages-in-doc],
406   [AS_HELP_STRING([--enable-manpages-in-doc],
407                   m4_normalize([include man pages in HTML documentation
408                                 (requires sphinx; default disabled)]))],
409   [case "$enableval" in
410       yes) manpages_in_doc=yes ;;
411       no) manpages_in_doc= ;;
412       *)
413         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
414         ;;
415     esac
416   ],
417   [manpages_in_doc=])
418 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
419 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
420
421 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
422   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
423 fi
424
425 # Check for graphviz (dot)
426 AC_ARG_VAR(DOT, [dot path])
427 AC_PATH_PROG(DOT, [dot], [])
428 if test -z "$DOT"
429 then
430   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
431                             documentation rebuild not possible]))
432 fi
433
434 # Check for pylint
435 AC_ARG_VAR(PYLINT, [pylint path])
436 AC_PATH_PROG(PYLINT, [pylint], [])
437 if test -z "$PYLINT"
438 then
439   AC_MSG_WARN([pylint not found, checking code will not be possible])
440 fi
441
442 # Check for pep8
443 AC_ARG_VAR(PEP8, [pep8 path])
444 AC_PATH_PROG(PEP8, [pep8], [])
445 if test -z "$PEP8"
446 then
447   AC_MSG_WARN([pep8 not found, checking code will not be complete])
448 fi
449 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
450
451 # Check for python-coverage
452 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
453 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
454 if test -z "$PYCOVERAGE"
455 then
456   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
457                             Python test coverage will not be possible]))
458 fi
459
460 # Check for socat
461 AC_ARG_VAR(SOCAT, [socat path])
462 AC_PATH_PROG(SOCAT, [socat], [])
463 if test -z "$SOCAT"
464 then
465   AC_MSG_ERROR([socat not found])
466 fi
467
468 # Check for qemu-img
469 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
470 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
471 if test -z "$QEMUIMG_PATH"
472 then
473   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
474 fi
475
476 # --enable-confd
477 ENABLE_CONFD=
478 AC_ARG_ENABLE([confd],
479   [AS_HELP_STRING([--enable-confd],
480   [enable the ganeti-confd daemon (default: check)])],
481   [],
482   [enable_confd=check])
483
484 ENABLE_MOND=
485 AC_ARG_ENABLE([monitoring],
486   [AS_HELP_STRING([--enable-monitoring],
487   [enable the ganeti monitoring daemon (default: check)])],
488   [],
489   [enable_monitoring=check])
490
491 # Check for ghc
492 AC_ARG_VAR(GHC, [ghc path])
493 AC_PATH_PROG(GHC, [ghc], [])
494 if test -z "$GHC"; then
495   AC_MSG_FAILURE([ghc not found, compilation will not possible])
496 fi
497
498 AC_MSG_CHECKING([checking for extra GHC flags])
499 GHC_BYVERSION_FLAGS=
500 # check for GHC supported flags that vary accross versions
501 for flag in -fwarn-incomplete-uni-patterns; do
502   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
503    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
504   fi
505 done
506 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
507 AC_SUBST(GHC_BYVERSION_FLAGS)
508
509 # Check for ghc-pkg
510 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
511 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
512 if test -z "$GHC_PKG"; then
513   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
514 fi
515
516 # check for modules, first custom/special checks
517 AC_MSG_NOTICE([checking for required haskell modules])
518 HS_PARALLEL3=
519 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
520                  [AC_GHC_PKG_REQUIRE(parallel)], t)
521 AC_SUBST(HS_PARALLEL3)
522
523 # and now standard modules
524 AC_GHC_PKG_REQUIRE(curl)
525 AC_GHC_PKG_REQUIRE(json)
526 AC_GHC_PKG_REQUIRE(network)
527 AC_GHC_PKG_REQUIRE(mtl)
528 AC_GHC_PKG_REQUIRE(bytestring)
529 AC_GHC_PKG_REQUIRE(utf8-string)
530
531 # extra modules for confd functionality
532 HS_REGEX_PCRE=-DNO_REGEX_PCRE
533 has_confd=False
534 if test "$enable_confd" != no; then
535   CONFD_PKG=
536   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
537                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
538   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
539   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
540   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
541   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
542   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
543   if test -z "$CONFD_PKG"; then
544     has_confd=True
545   elif test "$enable_confd" = check; then
546     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
547                               not found ($CONFD_PKG), confd disabled]))
548   else
549     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
550                                  required libraries were not found:
551                                  $CONFD_PKG]))
552   fi
553 fi
554 AC_SUBST(HS_REGEX_PCRE)
555 if test "$has_confd" = True; then
556   AC_MSG_NOTICE([Enabling confd usage])
557 fi
558 AC_SUBST(ENABLE_CONFD, $has_confd)
559 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
560
561 #extra modules for monitoring daemon functionality
562 has_monitoring=False
563 if test "$enable_monitoring" != no; then
564   MONITORING_PKG=
565   AC_GHC_PKG_CHECK([attoparsec], [],
566                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
567   AC_GHC_PKG_CHECK([snap-server], [],
568                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
569   MONITORING_DEP=
570   if test "$has_confd" = False; then
571     MONITORING_DEP="$MONITORING_DEP confd"
572   fi
573   has_monitoring_pkg=False
574   if test -z "$MONITORING_PKG"; then
575     has_monitoring_pkg=True
576   elif test "$enable_monitoring" = check; then
577     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
578                               daemon were not found ($MONITORING_PKG),
579                               monitoring disabled]))
580   else
581     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
582                                  required libraries were not found:
583                                  $MONITORING_PKG]))
584   fi
585   has_monitoring_dep=False
586   if test -z "$MONITORING_DEP"; then
587     has_monitoring_dep=True
588   elif test "$enable_monitoring" = check; then
589     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
590                               monitoring agent were not enabled
591                               ($MONITORING_DEP), monitoring disabled]))
592   else
593     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
594                                  required optional Ganeti components were not
595                                  found: $MONITORING_DEP]))
596   fi
597
598 fi
599 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
600   has_monitoring=True
601   AC_MSG_NOTICE([Enabling the monitoring agent usage])
602 fi
603 AC_SUBST(ENABLE_MOND, $has_monitoring)
604 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
605
606 # development modules
607 HS_NODEV=
608 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
609 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
610 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
611 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
612 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
613 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
614 #        that are needed to execute the tests, avoiding the duplication
615 #        of the checks.
616 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
617 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
618 if test -n "$HS_NODEV"; then
619    AC_MSG_WARN(m4_normalize([Required development modules were not found,
620                              you won't be able to run Haskell unittests]))
621 else
622    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
623 fi
624 AC_SUBST(HS_NODEV)
625
626 HTOOLS=yes
627 AC_SUBST(HTOOLS)
628
629 # --enable-split-query
630 ENABLE_SPLIT_QUERY=
631 AC_ARG_ENABLE([split-query],
632   [AS_HELP_STRING([--enable-split-query],
633   [enable use of custom query daemon via confd])],
634   [[case "$enableval" in
635       no)
636         enable_split_query=False
637         ;;
638       yes)
639         enable_split_query=True
640         ;;
641       *)
642         echo "Invalid value for enable-confd '$enableval'"
643         exit 1
644         ;;
645     esac
646   ]],
647   [[case "x${has_confd}x" in
648      xTruex)
649        enable_split_query=True
650        ;;
651      *)
652        enable_split_query=False
653        ;;
654    esac]])
655 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
656
657 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
658   AC_MSG_ERROR([Split queries require the confd daemon])
659 fi
660
661 if test x$enable_split_query = xTrue; then
662   AC_MSG_NOTICE([Split query functionality enabled])
663 fi
664
665 # Check for HsColour
666 HS_APIDOC=no
667 AC_ARG_VAR(HSCOLOUR, [HsColour path])
668 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
669 if test -z "$HSCOLOUR"; then
670   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
671                             not be generated]))
672 fi
673
674 # Check for haddock
675 AC_ARG_VAR(HADDOCK, [haddock path])
676 AC_PATH_PROG(HADDOCK, [haddock], [])
677 if test -z "$HADDOCK"; then
678   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
679                             not be generated]))
680 fi
681 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
682   HS_APIDOC=yes
683 fi
684 AC_SUBST(HS_APIDOC)
685
686 # Check for hlint
687 AC_ARG_VAR(HLINT, [hlint path])
688 AC_PATH_PROG(HLINT, [hlint], [])
689 if test -z "$HLINT"; then
690   AC_MSG_WARN([hlint not found, checking code will not be possible])
691 fi
692
693 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
694   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
695                              htools support is not enabled]))
696 fi
697
698 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
699 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
700 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
701 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
702
703 # Check for fakeroot
704 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
705 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
706 if test -z "$FAKEROOT_PATH"; then
707   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
708                             will not be executed]))
709 fi
710 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
711
712 SOCAT_USE_ESCAPE=
713 AC_ARG_ENABLE([socat-escape],
714   [AS_HELP_STRING([--enable-socat-escape],
715     [use escape functionality available in socat >= 1.7 (default: detect
716      automatically)])],
717   [[if test "$enableval" = yes; then
718       SOCAT_USE_ESCAPE=True
719     else
720       SOCAT_USE_ESCAPE=False
721     fi
722   ]])
723
724 if test -z "$SOCAT_USE_ESCAPE"
725 then
726   if $SOCAT -hh | grep -w -q escape; then
727     SOCAT_USE_ESCAPE=True
728   else
729     SOCAT_USE_ESCAPE=False
730   fi
731 fi
732
733 AC_SUBST(SOCAT_USE_ESCAPE)
734
735 SOCAT_USE_COMPRESS=
736 AC_ARG_ENABLE([socat-compress],
737   [AS_HELP_STRING([--enable-socat-compress],
738     [use OpenSSL compression option available in patched socat builds
739      (see INSTALL for details; default: detect automatically)])],
740   [[if test "$enableval" = yes; then
741       SOCAT_USE_COMPRESS=True
742     else
743       SOCAT_USE_COMPRESS=False
744     fi
745   ]])
746
747 if test -z "$SOCAT_USE_COMPRESS"
748 then
749   if $SOCAT -hhh | grep -w -q openssl-compress; then
750     SOCAT_USE_COMPRESS=True
751   else
752     SOCAT_USE_COMPRESS=False
753   fi
754 fi
755
756 AC_SUBST(SOCAT_USE_COMPRESS)
757
758 if man --help | grep -q -e --warnings
759 then
760   MAN_HAS_WARNINGS=1
761 else
762   MAN_HAS_WARNINGS=
763   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
764                             will not be possible]))
765 fi
766
767 AC_SUBST(MAN_HAS_WARNINGS)
768
769 # Check for Python
770 AM_PATH_PYTHON(2.6)
771
772 AC_PYTHON_MODULE(OpenSSL, t)
773 AC_PYTHON_MODULE(simplejson, t)
774 AC_PYTHON_MODULE(pyparsing, t)
775 AC_PYTHON_MODULE(pyinotify, t)
776 AC_PYTHON_MODULE(pycurl, t)
777 AC_PYTHON_MODULE(bitarray, t)
778 AC_PYTHON_MODULE(ipaddr, t)
779 AC_PYTHON_MODULE(affinity)
780 AC_PYTHON_MODULE(paramiko)
781
782 # Development-only Python modules
783 PY_NODEV=
784 AC_PYTHON_MODULE(yaml)
785 if test $HAVE_PYMOD_YAML == "no"; then
786   PY_NODEV="$PY_NODEV yaml"
787 fi
788
789 if test -n "$PY_NODEV"; then
790   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
791                             found, you won't be able to run Python unittests]))
792 else
793    AC_MSG_NOTICE([Python development modules found, unittests enabled])
794 fi
795 AC_SUBST(PY_NODEV)
796 AM_CONDITIONAL([PY_NODEV], [test -n $PY_NODEV])
797
798 AC_CONFIG_FILES([ Makefile ])
799
800 AC_OUTPUT