Bump revision number
[ganeti-github.git] / configure.ac
1 # Configure script for Ganeti
2 m4_define([gnt_version_major], [2])
3 m4_define([gnt_version_minor], [9])
4 m4_define([gnt_version_revision], [7])
5 m4_define([gnt_version_suffix], [])
6 m4_define([gnt_version_full],
7           m4_format([%d.%d.%d%s],
8                     gnt_version_major, gnt_version_minor,
9                     gnt_version_revision, gnt_version_suffix))
10
11 AC_PREREQ(2.59)
12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
13 AC_CONFIG_AUX_DIR(autotools)
14 AC_CONFIG_SRCDIR(configure)
15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability]
16                  m4_esyscmd([case `automake --version | head -n 1` in
17                              *1.11*);;
18                              *) echo serial-tests;;
19                              esac]))
20
21 AC_SUBST([VERSION_MAJOR], gnt_version_major)
22 AC_SUBST([VERSION_MINOR], gnt_version_minor)
23 AC_SUBST([VERSION_REVISION], gnt_version_revision)
24 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
25 AC_SUBST([VERSION_FULL], gnt_version_full)
26
27 # --with-haskell-flags=
28 AC_ARG_WITH([haskell-flags],
29   [AS_HELP_STRING([--with-haskell-flags=FLAGS],
30     [Extra flags to pass to GHC]
31   )],
32   [hextra_configure="$withval"],
33   [hextra_configure=""])
34 AC_SUBST(HEXTRA_CONFIGURE, $hextra_configure)
35
36 # --with-ssh-initscript=...
37 AC_ARG_WITH([ssh-initscript],
38   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
39     [SSH init script to use (default is /etc/init.d/ssh)]
40   )],
41   [ssh_initd_script="$withval"],
42   [ssh_initd_script="/etc/init.d/ssh"])
43 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
44
45 # --with-export-dir=...
46 AC_ARG_WITH([export-dir],
47   [AS_HELP_STRING([--with-export-dir=DIR],
48     [directory to use by default for instance image]
49     [ exports (default is /srv/ganeti/export)]
50   )],
51   [export_dir="$withval"],
52   [export_dir="/srv/ganeti/export"])
53 AC_SUBST(EXPORT_DIR, $export_dir)
54
55 # --with-ssh-config-dir=...
56 AC_ARG_WITH([ssh-config-dir],
57   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
58     [ directory with ssh host keys ]
59     [ (default is /etc/ssh)]
60   )],
61   [ssh_config_dir="$withval"],
62   [ssh_config_dir="/etc/ssh"])
63 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
64
65 # --with-xen-config-dir=...
66 AC_ARG_WITH([xen-config-dir],
67   [AS_HELP_STRING([--with-xen-config-dir=DIR],
68                   m4_normalize([Xen configuration directory
69                                 (default: /etc/xen)]))],
70   [xen_config_dir="$withval"],
71   [xen_config_dir=/etc/xen])
72 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
73
74 # --with-os-search-path=...
75 # do a bit of black sed magic to for quoting of the strings in the list
76 AC_ARG_WITH([os-search-path],
77   [AS_HELP_STRING([--with-os-search-path=LIST],
78     [comma separated list of directories to]
79     [ search for OS images (default is /srv/ganeti/os)]
80   )],
81   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
82   [os_search_path="'/srv/ganeti/os'"])
83 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
84
85 # --with-extstorage-search-path=...
86 # same black sed magic for quoting of the strings in the list
87 AC_ARG_WITH([extstorage-search-path],
88   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
89     [comma separated list of directories to]
90     [ search for External Storage Providers]
91     [ (default is /srv/ganeti/extstorage)]
92   )],
93   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
94   [es_search_path="'/srv/ganeti/extstorage'"])
95 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
96
97 # --with-iallocator-search-path=...
98 # do a bit of black sed magic to for quoting of the strings in the list
99 AC_ARG_WITH([iallocator-search-path],
100   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
101     [comma separated list of directories to]
102     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
103   )],
104   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
105   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
106 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
107
108 # --with-xen-bootloader=...
109 AC_ARG_WITH([xen-bootloader],
110   [AS_HELP_STRING([--with-xen-bootloader=PATH],
111     [bootloader for Xen hypervisor (default is empty)]
112   )],
113   [xen_bootloader="$withval"],
114   [xen_bootloader=])
115 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
116
117 # --with-xen-kernel=...
118 AC_ARG_WITH([xen-kernel],
119   [AS_HELP_STRING([--with-xen-kernel=PATH],
120     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
121   )],
122   [xen_kernel="$withval"],
123   [xen_kernel="/boot/vmlinuz-3-xenU"])
124 AC_SUBST(XEN_KERNEL, $xen_kernel)
125
126 # --with-xen-initrd=...
127 AC_ARG_WITH([xen-initrd],
128   [AS_HELP_STRING([--with-xen-initrd=PATH],
129     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
130   )],
131   [xen_initrd="$withval"],
132   [xen_initrd="/boot/initrd-3-xenU"])
133 AC_SUBST(XEN_INITRD, $xen_initrd)
134
135 # --with-kvm-kernel=...
136 AC_ARG_WITH([kvm-kernel],
137   [AS_HELP_STRING([--with-kvm-kernel=PATH],
138     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
139   )],
140   [kvm_kernel="$withval"],
141   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
142 AC_SUBST(KVM_KERNEL, $kvm_kernel)
143
144 # --with-kvm-path=...
145 AC_ARG_WITH([kvm-path],
146   [AS_HELP_STRING([--with-kvm-path=PATH],
147     [absolute path to the kvm binary]
148     [ (default is /usr/bin/kvm)]
149   )],
150   [kvm_path="$withval"],
151   [kvm_path="/usr/bin/kvm"])
152 AC_SUBST(KVM_PATH, $kvm_path)
153
154 # --with-lvm-stripecount=...
155 AC_ARG_WITH([lvm-stripecount],
156   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
157     [the default number of stripes to use for LVM volumes]
158     [ (default is 1)]
159   )],
160   [lvm_stripecount="$withval"],
161   [lvm_stripecount=1])
162 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
163
164 # --with-ssh-login-user=...
165 AC_ARG_WITH([ssh-login-user],
166   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
167     [user to use for SSH logins within the cluster (default is root)]
168   )],
169   [ssh_login_user="$withval"],
170   [ssh_login_user=root])
171 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
172
173 # --with-ssh-console-user=...
174 AC_ARG_WITH([ssh-console-user],
175   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
176     [user to use for SSH logins to access instance consoles (default is root)]
177   )],
178   [ssh_console_user="$withval"],
179   [ssh_console_user=root])
180 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
181
182 # --with-default-user=...
183 AC_ARG_WITH([default-user],
184   [AS_HELP_STRING([--with-default-user=USERNAME],
185     [default user for daemons]
186     [ (default is to run all daemons as root)]
187   )],
188   [user_default="$withval"],
189   [user_default=root])
190
191 # --with-default-group=...
192 AC_ARG_WITH([default-group],
193   [AS_HELP_STRING([--with-default-group=GROUPNAME],
194     [default group for daemons]
195     [ (default is to run all daemons under group root)]
196   )],
197   [group_default="$withval"],
198   [group_default=root])
199
200 # --with-user-prefix=...
201 AC_ARG_WITH([user-prefix],
202   [AS_HELP_STRING([--with-user-prefix=PREFIX],
203     [prefix for daemon users]
204     [ (default is to run all daemons as root; use --with-default-user]
205     [ to change the default)]
206   )],
207   [user_masterd="${withval}masterd";
208    user_rapi="${withval}rapi";
209    user_confd="${withval}confd";
210    user_luxid="${withval}luxid";
211    user_noded="$user_default";
212    user_mond="$user_default"],
213   [user_masterd="$user_default";
214    user_rapi="$user_default";
215    user_confd="$user_default";
216    user_luxid="$user_default";
217    user_noded="$user_default";
218    user_mond="$user_default"])
219 AC_SUBST(MASTERD_USER, $user_masterd)
220 AC_SUBST(RAPI_USER, $user_rapi)
221 AC_SUBST(CONFD_USER, $user_confd)
222 AC_SUBST(LUXID_USER, $user_luxid)
223 AC_SUBST(NODED_USER, $user_noded)
224 AC_SUBST(MOND_USER, $user_mond)
225
226 # --with-group-prefix=...
227 AC_ARG_WITH([group-prefix],
228   [AS_HELP_STRING([--with-group-prefix=PREFIX],
229     [prefix for daemon POSIX groups]
230     [ (default is to run all daemons under group root; use]
231     [ --with-default-group to change the default)]
232   )],
233   [group_rapi="${withval}rapi";
234    group_admin="${withval}admin";
235    group_confd="${withval}confd";
236    group_luxid="${withval}luxid";
237    group_masterd="${withval}masterd";
238    group_noded="$group_default";
239    group_daemons="${withval}daemons";
240    group_mond="$group_default"],
241   [group_rapi="$group_default";
242    group_admin="$group_default";
243    group_confd="$group_default";
244    group_luxid="$group_default";
245    group_masterd="$group_default";
246    group_noded="$group_default";
247    group_daemons="$group_default";
248    group_mond="$group_default"])
249 AC_SUBST(RAPI_GROUP, $group_rapi)
250 AC_SUBST(ADMIN_GROUP, $group_admin)
251 AC_SUBST(CONFD_GROUP, $group_confd)
252 AC_SUBST(LUXID_GROUP, $group_luxid)
253 AC_SUBST(MASTERD_GROUP, $group_masterd)
254 AC_SUBST(NODED_GROUP, $group_noded)
255 AC_SUBST(DAEMONS_GROUP, $group_daemons)
256 AC_SUBST(MOND_GROUP, $group_mond)
257
258 # Print the config to the user
259 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
260 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
261 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
262 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
263 AC_MSG_NOTICE([Group for daemons is $group_daemons])
264 AC_MSG_NOTICE([Group for clients is $group_admin])
265
266 # --enable-drbd-barriers
267 AC_ARG_ENABLE([drbd-barriers],
268   [AS_HELP_STRING([--enable-drbd-barriers],
269                   m4_normalize([enable the DRBD barriers functionality by
270                                 default (>= 8.0.12) (default: enabled)]))],
271   [[if test "$enableval" != no; then
272       DRBD_BARRIERS=n
273       DRBD_NO_META_FLUSH=False
274     else
275       DRBD_BARRIERS=bf
276       DRBD_NO_META_FLUSH=True
277     fi
278   ]],
279   [DRBD_BARRIERS=n
280    DRBD_NO_META_FLUSH=False
281   ])
282 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
283 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
284
285 # --enable-syslog[=no/yes/only]
286 AC_ARG_ENABLE([syslog],
287   [AS_HELP_STRING([--enable-syslog],
288     [enable use of syslog (default: disabled), one of no/yes/only])],
289   [[case "$enableval" in
290       no)
291         SYSLOG=no
292         ;;
293       yes)
294         SYSLOG=yes
295         ;;
296       only)
297         SYSLOG=only
298         ;;
299       *)
300         SYSLOG=
301         ;;
302     esac
303   ]],
304   [SYSLOG=no])
305
306 if test -z "$SYSLOG"
307 then
308   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
309 fi
310 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
311
312 AC_ARG_ENABLE([restricted-commands],
313   [AS_HELP_STRING([--enable-restricted-commands],
314                   m4_normalize([enable restricted commands in the node daemon
315                                 (default: disabled)]))],
316   [[if test "$enableval" = no; then
317       enable_restricted_commands=False
318     else
319       enable_restricted_commands=True
320     fi
321   ]],
322   [enable_restricted_commands=False])
323 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
324
325 # --with-disk-separator=...
326 AC_ARG_WITH([disk-separator],
327   [AS_HELP_STRING([--with-disk-separator=STRING],
328     [Disk index separator, useful if the default of ':' is handled]
329     [ specially by the hypervisor]
330   )],
331   [disk_separator="$withval"],
332   [disk_separator=":"])
333 AC_SUBST(DISK_SEPARATOR, $disk_separator)
334
335 # Check common programs
336 AC_PROG_INSTALL
337 AC_PROG_LN_S
338
339 # Check for the ip command
340 AC_ARG_VAR(IP_PATH, [ip path])
341 AC_PATH_PROG(IP_PATH, [ip], [])
342 if test -z "$IP_PATH"
343 then
344   AC_MSG_ERROR([ip command not found])
345 fi
346
347 # Check for pandoc
348 AC_ARG_VAR(PANDOC, [pandoc path])
349 AC_PATH_PROG(PANDOC, [pandoc], [])
350 if test -z "$PANDOC"
351 then
352   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
353 fi
354
355 # Check for python-sphinx
356 AC_ARG_VAR(SPHINX, [sphinx-build path])
357 AC_PATH_PROG(SPHINX, [sphinx-build], [])
358 if test -z "$SPHINX"
359 then
360   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
361                             not be possible]))
362 else
363   # Sphinx exits with code 1 when it prints its usage
364   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
365
366   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
367     AC_MSG_ERROR([Unable to determine Sphinx version])
368
369   # Note: Character classes ([...]) need to be double quoted due to autoconf
370   # using m4
371   elif ! echo "$sphinxver" | grep -q -E \
372        '^Sphinx[[[:space:]]]+(\(sphinx-build\)[[[:space:]]]+|v)[[1-9]]\>'; then
373     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
374   fi
375 fi
376 AM_CONDITIONAL([HAS_SPHINX], [test -n "$SPHINX"])
377
378 AC_ARG_ENABLE([manpages-in-doc],
379   [AS_HELP_STRING([--enable-manpages-in-doc],
380                   m4_normalize([include man pages in HTML documentation
381                                 (requires sphinx; default disabled)]))],
382   [case "$enableval" in
383       yes) manpages_in_doc=yes ;;
384       no) manpages_in_doc= ;;
385       *)
386         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
387         ;;
388     esac
389   ],
390   [manpages_in_doc=])
391 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
392 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
393
394 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
395   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
396 fi
397
398 # Check for graphviz (dot)
399 AC_ARG_VAR(DOT, [dot path])
400 AC_PATH_PROG(DOT, [dot], [])
401 if test -z "$DOT"
402 then
403   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
404                             documentation rebuild not possible]))
405 fi
406
407 # Check for pylint
408 AC_ARG_VAR(PYLINT, [pylint path])
409 AC_PATH_PROG(PYLINT, [pylint], [])
410 if test -z "$PYLINT"
411 then
412   AC_MSG_WARN([pylint not found, checking code will not be possible])
413 fi
414
415 # Check for pep8
416 AC_ARG_VAR(PEP8, [pep8 path])
417 AC_PATH_PROG(PEP8, [pep8], [])
418 if test -z "$PEP8"
419 then
420   AC_MSG_WARN([pep8 not found, checking code will not be complete])
421 fi
422 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
423
424 # Check for python-coverage
425 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
426 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
427 if test -z "$PYCOVERAGE"
428 then
429   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
430                             Python test coverage will not be possible]))
431 fi
432
433 # Check for socat
434 AC_ARG_VAR(SOCAT, [socat path])
435 AC_PATH_PROG(SOCAT, [socat], [])
436 if test -z "$SOCAT"
437 then
438   AC_MSG_ERROR([socat not found])
439 fi
440
441 # Check for qemu-img
442 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
443 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
444 if test -z "$QEMUIMG_PATH"
445 then
446   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
447 fi
448
449 # --enable-confd
450 ENABLE_CONFD=
451 AC_ARG_ENABLE([confd],
452   [AS_HELP_STRING([--enable-confd],
453   [enable the ganeti-confd daemon (default: check)])],
454   [],
455   [enable_confd=check])
456
457 ENABLE_MOND=
458 AC_ARG_ENABLE([monitoring],
459   [AS_HELP_STRING([--enable-monitoring],
460   [enable the ganeti monitoring daemon (default: check)])],
461   [],
462   [enable_monitoring=check])
463
464 # Check for ghc
465 AC_ARG_VAR(GHC, [ghc path])
466 AC_PATH_PROG(GHC, [ghc], [])
467 if test -z "$GHC"; then
468   AC_MSG_FAILURE([ghc not found, compilation will not possible])
469 fi
470
471 AC_MSG_CHECKING([checking for extra GHC flags])
472 GHC_BYVERSION_FLAGS=
473 # check for GHC supported flags that vary accross versions
474 for flag in -fwarn-incomplete-uni-patterns; do
475   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
476    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
477   fi
478 done
479 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
480 AC_SUBST(GHC_BYVERSION_FLAGS)
481
482 # Check for ghc-pkg
483 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
484 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
485 if test -z "$GHC_PKG"; then
486   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
487 fi
488
489 # check for modules, first custom/special checks
490 AC_MSG_NOTICE([checking for required haskell modules])
491 HS_PARALLEL3=
492 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
493                  [AC_GHC_PKG_REQUIRE(parallel)], t)
494 AC_SUBST(HS_PARALLEL3)
495
496 # and now standard modules
497 AC_GHC_PKG_REQUIRE(curl)
498 AC_GHC_PKG_REQUIRE(json)
499 AC_GHC_PKG_REQUIRE(network)
500 AC_GHC_PKG_REQUIRE(mtl)
501 AC_GHC_PKG_REQUIRE(bytestring)
502 AC_GHC_PKG_REQUIRE(utf8-string)
503 AC_GHC_PKG_REQUIRE(hslogger)
504
505 # extra modules for confd functionality
506 HS_REGEX_PCRE=-DNO_REGEX_PCRE
507 has_confd=False
508 if test "$enable_confd" != no; then
509   CONFD_PKG=
510   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
511                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
512   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
513   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
514   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
515   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
516   if test -z "$CONFD_PKG"; then
517     has_confd=True
518   elif test "$enable_confd" = check; then
519     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
520                               not found ($CONFD_PKG), confd disabled]))
521   else
522     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
523                                  required libraries were not found:
524                                  $CONFD_PKG]))
525   fi
526 fi
527 AC_SUBST(HS_REGEX_PCRE)
528 if test "$has_confd" = True; then
529   AC_MSG_NOTICE([Enabling confd usage])
530 fi
531 AC_SUBST(ENABLE_CONFD, $has_confd)
532 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
533
534 #extra modules for monitoring daemon functionality
535 has_monitoring=False
536 if test "$enable_monitoring" != no; then
537   MONITORING_PKG=
538   AC_GHC_PKG_CHECK([attoparsec], [],
539                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
540   AC_GHC_PKG_CHECK([snap-server], [],
541                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
542   AC_GHC_PKG_CHECK([process], [],
543                    [MONITORING_PKG="$MONITORING_PKG process"])
544   MONITORING_DEP=
545   if test "$has_confd" = False; then
546     MONITORING_DEP="$MONITORING_DEP confd"
547   fi
548   has_monitoring_pkg=False
549   if test -z "$MONITORING_PKG"; then
550     has_monitoring_pkg=True
551   elif test "$enable_monitoring" = check; then
552     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
553                               daemon were not found ($MONITORING_PKG),
554                               monitoring disabled]))
555   else
556     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
557                                  required libraries were not found:
558                                  $MONITORING_PKG]))
559   fi
560   has_monitoring_dep=False
561   if test -z "$MONITORING_DEP"; then
562     has_monitoring_dep=True
563   elif test "$enable_monitoring" = check; then
564     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
565                               monitoring agent were not enabled
566                               ($MONITORING_DEP), monitoring disabled]))
567   else
568     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
569                                  required optional Ganeti components were not
570                                  found: $MONITORING_DEP]))
571   fi
572
573 fi
574 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
575   has_monitoring=True
576   AC_MSG_NOTICE([Enabling the monitoring agent usage])
577 fi
578 AC_SUBST(ENABLE_MOND, $has_monitoring)
579 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
580
581 # development modules
582 HS_NODEV=
583 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
584 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
585 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
586 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
587 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
588 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
589 #        that are needed to execute the tests, avoiding the duplication
590 #        of the checks.
591 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
592 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
593 AC_GHC_PKG_CHECK([process], [], [HS_NODEV=1])
594 AC_GHC_PKG_CHECK([snap-server], [], [HS_NODEV=1])
595 AC_GHC_PKG_CHECK([regex-pcre], [], [HS_NODEV=1])
596 AC_GHC_PKG_CHECK([Crypto], [], [HS_NODEV=1])
597 AC_GHC_PKG_CHECK([text], [], [HS_NODEV=1])
598 AC_GHC_PKG_CHECK([hinotify], [], [HS_NODEV=1])
599 if test -n "$HS_NODEV"; then
600    AC_MSG_WARN(m4_normalize([Required development modules were not found,
601                              you won't be able to run Haskell unittests]))
602 else
603    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
604 fi
605 AC_SUBST(HS_NODEV)
606
607 HTOOLS=yes
608 AC_SUBST(HTOOLS)
609
610 # --enable-split-query
611 ENABLE_SPLIT_QUERY=
612 AC_ARG_ENABLE([split-query],
613   [AS_HELP_STRING([--enable-split-query],
614   [enable use of custom query daemon via confd])],
615   [[case "$enableval" in
616       no)
617         enable_split_query=False
618         ;;
619       yes)
620         enable_split_query=True
621         ;;
622       *)
623         echo "Invalid value for enable-confd '$enableval'"
624         exit 1
625         ;;
626     esac
627   ]],
628   [[case "x${has_confd}x" in
629      xTruex)
630        enable_split_query=True
631        ;;
632      *)
633        enable_split_query=False
634        ;;
635    esac]])
636 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
637
638 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
639   AC_MSG_ERROR([Split queries require the confd daemon])
640 fi
641
642 if test x$enable_split_query = xTrue; then
643   AC_MSG_NOTICE([Split query functionality enabled])
644 fi
645
646 # Check for HsColour
647 HS_APIDOC=no
648 AC_ARG_VAR(HSCOLOUR, [HsColour path])
649 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
650 if test -z "$HSCOLOUR"; then
651   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
652                             not be generated]))
653 fi
654
655 # Check for haddock
656 AC_ARG_VAR(HADDOCK, [haddock path])
657 AC_PATH_PROG(HADDOCK, [haddock], [])
658 if test -z "$HADDOCK"; then
659   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
660                             not be generated]))
661 fi
662 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
663   HS_APIDOC=yes
664 fi
665 AC_SUBST(HS_APIDOC)
666
667 # Check for hlint
668 AC_ARG_VAR(HLINT, [hlint path])
669 AC_PATH_PROG(HLINT, [hlint], [])
670 if test -z "$HLINT"; then
671   AC_MSG_WARN([hlint not found, checking code will not be possible])
672 fi
673
674 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
675   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
676                              htools support is not enabled]))
677 fi
678
679 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
680 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
681 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
682 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
683
684 # Check for fakeroot
685 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
686 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
687 if test -z "$FAKEROOT_PATH"; then
688   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
689                             will not be executed]))
690 fi
691 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
692
693 SOCAT_USE_ESCAPE=
694 AC_ARG_ENABLE([socat-escape],
695   [AS_HELP_STRING([--enable-socat-escape],
696     [use escape functionality available in socat >= 1.7 (default: detect
697      automatically)])],
698   [[if test "$enableval" = yes; then
699       SOCAT_USE_ESCAPE=True
700     else
701       SOCAT_USE_ESCAPE=False
702     fi
703   ]])
704
705 if test -z "$SOCAT_USE_ESCAPE"
706 then
707   if $SOCAT -hh | grep -w -q escape; then
708     SOCAT_USE_ESCAPE=True
709   else
710     SOCAT_USE_ESCAPE=False
711   fi
712 fi
713
714 AC_SUBST(SOCAT_USE_ESCAPE)
715
716 SOCAT_USE_COMPRESS=
717 AC_ARG_ENABLE([socat-compress],
718   [AS_HELP_STRING([--enable-socat-compress],
719     [use OpenSSL compression option available in patched socat builds
720      (see INSTALL for details; default: detect automatically)])],
721   [[if test "$enableval" = yes; then
722       SOCAT_USE_COMPRESS=True
723     else
724       SOCAT_USE_COMPRESS=False
725     fi
726   ]])
727
728 if test -z "$SOCAT_USE_COMPRESS"
729 then
730   if $SOCAT -hhh | grep -w -q openssl-compress; then
731     SOCAT_USE_COMPRESS=True
732   else
733     SOCAT_USE_COMPRESS=False
734   fi
735 fi
736
737 AC_SUBST(SOCAT_USE_COMPRESS)
738
739 if man --help | grep -q -e --warnings
740 then
741   MAN_HAS_WARNINGS=1
742 else
743   MAN_HAS_WARNINGS=
744   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
745                             will not be possible]))
746 fi
747
748 AC_SUBST(MAN_HAS_WARNINGS)
749
750 # Check for Python
751 AM_PATH_PYTHON(2.6)
752
753 AC_PYTHON_MODULE(OpenSSL, t)
754 AC_PYTHON_MODULE(simplejson, t)
755 AC_PYTHON_MODULE(pyparsing, t)
756 AC_PYTHON_MODULE(pyinotify, t)
757 AC_PYTHON_MODULE(pycurl, t)
758 AC_PYTHON_MODULE(bitarray, t)
759 AC_PYTHON_MODULE(ipaddr, t)
760 AC_PYTHON_MODULE(mock)
761 AC_PYTHON_MODULE(affinity)
762 AC_PYTHON_MODULE(paramiko)
763
764 # Development-only Python modules
765 PY_NODEV=
766 AC_PYTHON_MODULE(yaml)
767 if test $HAVE_PYMOD_YAML == "no"; then
768   PY_NODEV="$PY_NODEV yaml"
769 fi
770
771 if test -n "$PY_NODEV"; then
772   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
773                             found, you won't be able to run Python unittests]))
774 else
775   AC_MSG_NOTICE([Python development modules found, unittests enabled])
776 fi
777 AC_SUBST(PY_NODEV)
778 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
779
780 AC_CONFIG_FILES([ Makefile ])
781
782 AC_OUTPUT